154 lines
6.2 KiB
Markdown
154 lines
6.2 KiB
Markdown
# FileReadDatetime
|
||
|
||
Reads from the file of CSV type a string of one of the formats: "YYYY.MM.DD HH:MI:SS", "YYYY.MM.DD" or "HH:MI:SS" - and converts it into a value of datetime type.
|
||
|
||
```
|
||
datetime FileReadDatetime(
|
||
int file_handle // File handle
|
||
);
|
||
|
||
```
|
||
|
||
Parameters
|
||
|
||
file_handle
|
||
|
||
[in] File descriptor returned by [FileOpen()](/en/docs/files/fileopen).
|
||
|
||
Return Value
|
||
|
||
The value of datetime type.
|
||
|
||
Example (the file obtained after executing the example for [FileWrite](/en/docs/files/filewrite) function is used here)
|
||
|
||
```
|
||
//+------------------------------------------------------------------+
|
||
//| Demo_FileReadDateTime.mq5 |
|
||
//| Copyright 2013, MetaQuotes Software Corp. |
|
||
//| https://www.mql5.com |
|
||
//+------------------------------------------------------------------+
|
||
#property copyright "Copyright 2013, MetaQuotes Software Corp."
|
||
#property link "https://www.mql5.com"
|
||
#property version "1.00"
|
||
#property indicator_chart_window
|
||
#property indicator_buffers 2
|
||
#property indicator_plots 2
|
||
//---- plot Label1
|
||
#property indicator_label1 "UpSignal"
|
||
#property indicator_type1 DRAW_ARROW
|
||
#property indicator_color1 clrRed
|
||
#property indicator_style1 STYLE_SOLID
|
||
#property indicator_width1 4
|
||
//---- plot Label2
|
||
#property indicator_label2 "DownSignal"
|
||
#property indicator_type2 DRAW_ARROW
|
||
#property indicator_color2 clrRed
|
||
#property indicator_style2 STYLE_SOLID
|
||
#property indicator_width2 4
|
||
//--- parameters for data reading
|
||
input string InpFileName="MACD.csv"; // file name
|
||
input string InpDirectoryName="Data"; // directory name
|
||
//--- global variables
|
||
int ind=0; // index
|
||
double upbuff[]; // indicator buffers of up arrows
|
||
double downbuff[]; // indicator buffer of down arrows
|
||
bool sign_buff[]; // signal array (true - buy, false - sell)
|
||
datetime time_buff[]; // array of signals' arrival time
|
||
int size=0; // size of signal arrays
|
||
//+------------------------------------------------------------------+
|
||
//| Custom indicator initialization function |
|
||
//+------------------------------------------------------------------+
|
||
int OnInit()
|
||
{
|
||
//--- open the file
|
||
ResetLastError();
|
||
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_CSV);
|
||
if(file_handle!=INVALID_HANDLE)
|
||
{
|
||
PrintFormat("%s file is open for reading",InpFileName);
|
||
//--- first, read the number of signals
|
||
size=(int)FileReadNumber(file_handle);
|
||
//--- allocate memory for the arrays
|
||
ArrayResize(sign_buff,size);
|
||
ArrayResize(time_buff,size);
|
||
//--- read data from the file
|
||
for(int i=0;i<size;i++)
|
||
{
|
||
//--- signal time
|
||
time_buff[i]=FileReadDatetime(file_handle);
|
||
//--- signal value
|
||
sign_buff[i]=FileReadBool(file_handle);
|
||
}
|
||
//--- close the file
|
||
FileClose(file_handle);
|
||
}
|
||
else
|
||
{
|
||
PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());
|
||
return(INIT_FAILED);
|
||
}
|
||
//--- binding the arrays
|
||
SetIndexBuffer(0,upbuff,INDICATOR_DATA);
|
||
SetIndexBuffer(1,downbuff,INDICATOR_DATA);
|
||
//--- set the symbol code for drawing in PLOT_ARROW
|
||
PlotIndexSetInteger(0,PLOT_ARROW,241);
|
||
PlotIndexSetInteger(1,PLOT_ARROW,242);
|
||
//---- set the indicator values that will not be seen on the chart
|
||
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
|
||
PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0);
|
||
//---
|
||
return(INIT_SUCCEEDED);
|
||
}
|
||
//+------------------------------------------------------------------+
|
||
//| Custom indicator iteration function |
|
||
//+------------------------------------------------------------------+
|
||
int OnCalculate(const int rates_total,
|
||
const int prev_calculated,
|
||
const datetime &time[],
|
||
const double &open[],
|
||
const double &high[],
|
||
const double &low[],
|
||
const double &close[],
|
||
const long &tick_volume[],
|
||
const long &volume[],
|
||
const int &spread[])
|
||
{
|
||
ArraySetAsSeries(time,false);
|
||
ArraySetAsSeries(low,false);
|
||
ArraySetAsSeries(high,false);
|
||
//--- the loop for the bars that have not been handled yet
|
||
for(int i=prev_calculated;i<rates_total;i++)
|
||
{
|
||
//--- 0 by default
|
||
upbuff[i]=0;
|
||
downbuff[i]=0;
|
||
//--- check if any data is still present
|
||
if(ind<size)
|
||
{
|
||
for(int j=ind;j<size;j++)
|
||
{
|
||
//--- if dates coincide, use the value from the file
|
||
if(time[i]==time_buff[j])
|
||
{
|
||
//--- draw the arrow according to the signal
|
||
if(sign_buff[j])
|
||
upbuff[i]=high[i];
|
||
else
|
||
downbuff[i]=low[i];
|
||
//--- increase the counter
|
||
ind=j+1;
|
||
break;
|
||
}
|
||
}
|
||
}
|
||
}
|
||
//--- return value of prev_calculated for next call
|
||
return(rates_total);
|
||
}
|
||
|
||
```
|
||
|
||
See also
|
||
|
||
[Type datetime](/en/docs/basis/types/integer/datetime), [StringToTime](/en/docs/convert/stringtotime), [TimeToString](/en/docs/convert/timetostring), [FileWrite](/en/docs/files/filewrite)
|