184 lines
16 KiB
Plaintext
184 lines
16 KiB
Plaintext
//+---------------------------------------------------------------------+
|
|
//| X2MA.mq5 |
|
|
//| Copyright © 2011, Nikolay Kositsin |
|
|
//| Khabarovsk, farria@mail.redcom.ru |
|
|
//+---------------------------------------------------------------------+
|
|
//| Для работы индикатора следует положить файл SmoothAlgorithms.mqh |
|
|
//| в папку (директорию): каталог_данных_терминала\\MQL5\Include |
|
|
//+---------------------------------------------------------------------+
|
|
#property copyright "Copyright © 2011, Nikolay Kositsin"
|
|
#property link "farria@mail.redcom.ru"
|
|
//---- номер версии индикатора
|
|
#property version "1.00"
|
|
//---- отрисовка индикатора в главном окне
|
|
#property indicator_chart_window
|
|
//---- количество индикаторных буферов
|
|
#property indicator_buffers 1
|
|
//---- использовано всего одно графическое построение
|
|
#property indicator_plots 1
|
|
//+-----------------------------------+
|
|
//| Параметры отрисовки индикатора |
|
|
//+-----------------------------------+
|
|
//---- отрисовка индикатора в виде линии
|
|
#property indicator_type1 DRAW_LINE
|
|
//---- в качестве цвета линии индикатора использован сине-фиолетовый цвет
|
|
#property indicator_color1 clrBlueViolet
|
|
//---- линия индикатора - непрерывная кривая
|
|
#property indicator_style1 STYLE_SOLID
|
|
//---- толщина линии индикатора равна 1
|
|
#property indicator_width1 1
|
|
//---- отображение метки индикатора
|
|
#property indicator_label1 "X2MA"
|
|
|
|
//+-----------------------------------+
|
|
//| Описание класса CXMA |
|
|
//+-----------------------------------+
|
|
#include <SmoothAlgorithms.mqh>
|
|
//+-----------------------------------+
|
|
//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
|
|
CXMA XMA1,XMA2;
|
|
//+-----------------------------------+
|
|
//| объявление перечислений |
|
|
//+-----------------------------------+
|
|
enum Applied_price_ //Тип константы
|
|
{
|
|
PRICE_CLOSE_ = 1, //Close
|
|
PRICE_OPEN_, //Open
|
|
PRICE_HIGH_, //High
|
|
PRICE_LOW_, //Low
|
|
PRICE_MEDIAN_, //Median Price (HL/2)
|
|
PRICE_TYPICAL_, //Typical Price (HLC/3)
|
|
PRICE_WEIGHTED_, //Weighted Close (HLCC/4)
|
|
PRICE_SIMPL_, //Simpl Price (OC/2)
|
|
PRICE_QUARTER_, //Quarted Price (HLOC/4)
|
|
PRICE_TRENDFOLLOW0_, //TrendFollow_1 Price
|
|
PRICE_TRENDFOLLOW1_, //TrendFollow_2 Price
|
|
PRICE_DEMARK_ //Demark Price
|
|
};
|
|
//+-----------------------------------+
|
|
//| объявление перечислений |
|
|
//+-----------------------------------+
|
|
/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
|
|
{
|
|
MODE_SMA_, //SMA
|
|
MODE_EMA_, //EMA
|
|
MODE_SMMA_, //SMMA
|
|
MODE_LWMA_, //LWMA
|
|
MODE_JJMA, //JJMA
|
|
MODE_JurX, //JurX
|
|
MODE_ParMA, //ParMA
|
|
MODE_T3, //T3
|
|
MODE_VIDYA, //VIDYA
|
|
MODE_AMA, //AMA
|
|
}; */
|
|
//+-----------------------------------+
|
|
//| ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА |
|
|
//+-----------------------------------+
|
|
input Smooth_Method MA_Method1=MODE_SMA_; //метод усреднения первого сглаживания
|
|
input int Length1=12; //глубина первого сглаживания
|
|
input int Phase1=15; //параметр первого сглаживания,
|
|
//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
|
|
//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
|
|
input Smooth_Method MA_Method2=MODE_JJMA; //метод усреднения второго сглаживания
|
|
input int Length2 = 5; //глубина второго сглаживания
|
|
input int Phase2=15; //параметр второго сглаживания,
|
|
//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
|
|
//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
|
|
input Applied_price_ IPC=PRICE_CLOSE_;//ценовая константа
|
|
input int Shift=0; // сдвиг индикатора по горизонтали в барах
|
|
input int PriceShift=0; // cдвиг индикатора по вертикали в пунктах
|
|
//+-----------------------------------+
|
|
|
|
//---- объявление динамического массива, который будет в дальнейшем использован в качестве индикаторного буфера
|
|
double IndBuffer[];
|
|
|
|
//---- Объявление переменной значения вертикального сдвига мувинга
|
|
double dPriceShift;
|
|
//---- Объявление целых переменных начала отсчёта данных
|
|
int min_rates_total,min_rates_1,min_rates_;
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator initialization function |
|
|
//+------------------------------------------------------------------+
|
|
void OnInit()
|
|
{
|
|
//---- Инициализация переменных начала отсчёта данных
|
|
min_rates_1=GetStartBars(MA_Method1, Length1, Phase1);
|
|
min_rates_total=min_rates_1+GetStartBars(MA_Method2, Length2, Phase2);
|
|
//---- установка алертов на недопустимые значения внешних переменных
|
|
XMA1.XMALengthCheck("Length1", Length1);
|
|
XMA2.XMALengthCheck("Length2", Length2);
|
|
//---- установка алертов на недопустимые значения внешних переменных
|
|
XMA1.XMAPhaseCheck("Phase1", Phase1, MA_Method1);
|
|
XMA2.XMAPhaseCheck("Phase2", Phase2, MA_Method2);
|
|
|
|
//---- Инициализация сдвига по вертикали
|
|
dPriceShift=_Point*PriceShift;
|
|
|
|
//---- превращение динамического массива в индикаторный буфер
|
|
SetIndexBuffer(0,IndBuffer,INDICATOR_DATA);
|
|
//---- осуществление сдвига индикатора 1 по горизонтали
|
|
PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
|
|
//---- осуществление сдвига начала отсчёта отрисовки индикатора
|
|
PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
|
|
//---- установка значений индикатора, которые не будут видимы на графике
|
|
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
|
|
|
|
//---- инициализации переменной для короткого имени индикатора
|
|
string shortname;
|
|
string Smooth1=XMA1.GetString_MA_Method(MA_Method1);
|
|
string Smooth2=XMA1.GetString_MA_Method(MA_Method2);
|
|
StringConcatenate(shortname,"X2MA(",Length1,", ",Length2,", ",Smooth1,", ",Smooth2,")");
|
|
//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
|
|
IndicatorSetString(INDICATOR_SHORTNAME,shortname);
|
|
|
|
//--- определение точности отображения значений индикатора
|
|
IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
|
|
//---- завершение инициализации
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator iteration function |
|
|
//+------------------------------------------------------------------+
|
|
int OnCalculate(
|
|
const int rates_total, // количество истории в барах на текущем тике
|
|
const int prev_calculated,// количество истории в барах на предыдущем тике
|
|
const datetime &time[],
|
|
const double &open[],
|
|
const double &high[],
|
|
const double &low[],
|
|
const double &close[],
|
|
const long &tick_volume[],
|
|
const long &volume[],
|
|
const int &spread[]
|
|
)
|
|
{
|
|
//---- проверка количества баров на достаточность для расчёта
|
|
if(rates_total<min_rates_total) return(0);
|
|
|
|
//---- Объявление переменных с плавающей точкой
|
|
double price_,x1xma,x2xma;
|
|
//---- Объявление целых переменных и получение уже посчитанных баров
|
|
int first,bar;
|
|
|
|
//---- расчёт стартового номера first для цикла пересчёта баров
|
|
if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
|
|
first=0; // стартовый номер для расчёта всех баров
|
|
else first=prev_calculated-1; // стартовый номер для расчёта новых баров
|
|
|
|
//---- Основной цикл расчёта индикатора
|
|
for(bar=first; bar<rates_total && !IsStopped(); bar++)
|
|
{
|
|
//---- Вызов функции PriceSeries для получения входной цены price_
|
|
price_=PriceSeries(IPC,bar,open,low,high,close);
|
|
|
|
//---- Два вызова функции XMASeries.
|
|
//Во втором вызове параметр begin увеличен на StartBars1 т. к. это повторное XMA сглаживание
|
|
x1xma = XMA1.XMASeries( 0, prev_calculated, rates_total, MA_Method1, Phase1, Length1, price_, bar, false);
|
|
x2xma = XMA2.XMASeries(min_rates_1, prev_calculated, rates_total, MA_Method2, Phase2, Length2, x1xma, bar, false);
|
|
//----
|
|
IndBuffer[bar]=x2xma+dPriceShift;
|
|
}
|
|
//----
|
|
return(rates_total);
|
|
}
|
|
//+------------------------------------------------------------------+
|