Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

2025-06-24 00:50:24 +01:00
commit 884a002026
4971 changed files with 70275 additions and 0 deletions
@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `xvolume.mq5`
+
+### Screenshots:
+![Screenshot](xvolume.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,157 @@
+//+---------------------------------------------------------------------+
+//|                                                         XVolume.mq5 |
+//|                                 Copyright © 2012, Khlystov Vladimir |
+//|                                            http://cmillion.narod.ru |
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2012, cmillion@narod.ru"
+#property link      "http://cmillion.narod.ru" 
+//--- номер версии индикатора
+#property version   "1.00"
+//--- отрисовка индикатора в отдельном окне
+#property indicator_separate_window
+//--- количество индикаторных буферов 3
+#property indicator_buffers 3 
+//--- использовано всего два графических построения
+#property indicator_plots   2
+//+-----------------------------------+
+//| Параметры отрисовки индикатора 1  |
+//+-----------------------------------+
+//--- отрисовка индикатора в виде цветной гистограммы
+#property indicator_type1   DRAW_COLOR_HISTOGRAM
+//--- в качестве цветов гистограммы использованы
+#property indicator_color1 clrGray,clrDeepSkyBlue
+//--- линия индикатора - непрерывная кривая
+#property indicator_style1  STYLE_SOLID
+//--- толщина линии индикатора равна 2
+#property indicator_width1  2
+//--- отображение метки индикатора
+#property indicator_label1  "Volume"
+//+-----------------------------------+
+//| Параметры отрисовки индикатора 2  |
+//+-----------------------------------+
+//--- отрисовка индикатора в виде линии
+#property indicator_type2   DRAW_LINE
+//--- в качестве цвета линии индикатора использован Red цвет
+#property indicator_color2 clrRed
+//--- линия индикатора - непрерывная кривая
+#property indicator_style2  STYLE_SOLID
+//--- толщина линии индикатора равна 2
+#property indicator_width2  2
+//--- отображение метки индикатора
+#property indicator_label2  "XVolume"
+//+-----------------------------------+
+//| Описание класса CXMA              |
+//+-----------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+-----------------------------------+
+//--- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1;
+//+-----------------------------------+
+//| объявление перечислений           |
+//+-----------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+-----------------------------------+
+//| Входные параметры индикатора      |
+//+-----------------------------------+
+input ENUM_APPLIED_VOLUME VolumeType=VOLUME_TICK;  // Объём
+input Smooth_Method XMA_Method=MODE_SMA_;           // Метод усреднения
+input int XLength=12;                              // Глубина сглаживания                    
+input int XPhase=15;                               // Параметр сглаживания
+//--- XPhase: для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+//--- XPhase: для VIDIA это период CMO, для AMA это период медленной скользящей
+input int Shift=0;                                 // Сдвиг индикатора по горизонтали в барах
+//+-----------------------------------+
+//--- объявление динамических массивов, которые будут в дальнейшем использованы в качестве индикаторных буферов
+double IndBuffer1[],ColorIndBuffer1[],IndBuffer2[];
+//--- объявление целочисленных переменных начала отсчёта данных
+int min_rates_total;
+//+------------------------------------------------------------------+   
+//| XVolume indicator initialization function                        | 
+//+------------------------------------------------------------------+ 
+void OnInit()
+  {
+//--- инициализация переменных начала отсчёта данных
+   min_rates_total=XMA1.GetStartBars(XMA_Method,XLength,XPhase);
+//--- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMALengthCheck("XLength",XLength);
+   XMA1.XMAPhaseCheck("XPhase",XPhase,XMA_Method);
+//--- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,IndBuffer1,INDICATOR_DATA);
+//--- превращение динамического массива в цветовой буфер
+   SetIndexBuffer(1,ColorIndBuffer1,INDICATOR_COLOR_INDEX);
+//--- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(2,IndBuffer2,INDICATOR_DATA);   
+//--- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//--- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//--- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
+//--- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//--- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//--- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0);
+//--- инициализации переменной для короткого имени индикатора
+   string shortname;
+   string Smooth1=XMA1.GetString_MA_Method(XMA_Method);
+   StringConcatenate(shortname,"XVolume(",XLength,", ",Smooth1,")");
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,0);
+//--- завершение инициализации
+  }
+//+------------------------------------------------------------------+ 
+//| XVolume iteration function                                       | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[])
+  {
+//--- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+//--- объявление целочисленных переменных
+   int first,bar;
+   long vol;
+//--- расчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=0; // стартовый номер для расчёта всех баров
+   else first=prev_calculated-1; // стартовый номер для расчёта новых баров
+//--- основной цикл расчёта индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      if(VolumeType==VOLUME_TICK) vol=long(tick_volume[bar]);
+         else vol=long(volume[bar]);
+      IndBuffer2[bar]=XMA1.XMASeries(0,prev_calculated,rates_total,XMA_Method,XPhase,XLength,vol,bar,false);
+      IndBuffer1[bar]=double(vol);
+      if(vol>IndBuffer2[bar]) ColorIndBuffer1[bar]=1;
+      else ColorIndBuffer1[bar]=0;
+     }
+//---   
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+