Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

2025-06-24 00:50:24 +01:00
commit 884a002026
4971 changed files with 70275 additions and 0 deletions
@@ -0,0 +1,22 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `XEnvelopes_Digit.mq5`
+
+### Screenshots:
+![Screenshot](picture_1__1.png)
+![Screenshot](picture_2__1.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,256 @@
+//+---------------------------------------------------------------------+
+//|                                                XEnvelopes_Digit.mq5 |
+//|                                  Copyright © 2016, Nikolay Kositsin | 
+//|                                 Khabarovsk,   farria@mail.redcom.ru | 
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2016, Nikolay Kositsin"
+#property link "farria@mail.redcom.ru"
+#property description ""
+//---- номер версии индикатора
+#property version   "1.00"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+//---- количество индикаторных буферов 4
+#property indicator_buffers 4 
+//---- использовано всего три графических построения
+#property indicator_plots   3
+//+----------------------------------------------+
+//|  Параметры отрисовки облака                  |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде цветного облака
+#property indicator_type1   DRAW_FILLING
+//---- в качестве цвета облака использован
+#property indicator_color1  clrLavender
+//---- отображение метки индикатора
+#property indicator_label1  "XEnvelopes Cloud"
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора уровней      |
+//+----------------------------------------------+
+//---- отрисовка уровней в виде линий
+#property indicator_type2   DRAW_LINE
+#property indicator_type3   DRAW_LINE
+//---- ввыбор цветов уровней
+#property indicator_color2  clrLimeGreen
+#property indicator_color3  clrDeepPink
+//---- уровни - непрерывные кривые
+#property indicator_style2 STYLE_SOLID
+#property indicator_style3 STYLE_SOLID
+//---- толщина уровней равна 2
+#property indicator_width2  2
+#property indicator_width3  2
+//---- отображение меток уровней
+#property indicator_label2  "Upper XEnvelopes"
+#property indicator_label3  "Lower XEnvelopes"
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+enum Applied_price_      //Тип константы
+  {
+   PRICE_CLOSE_ = 1,     //Close
+   PRICE_OPEN_,          //Open
+   PRICE_HIGH_,          //High
+   PRICE_LOW_,           //Low
+   PRICE_MEDIAN_,        //Median Price (HL/2)
+   PRICE_TYPICAL_,       //Typical Price (HLC/3)
+   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
+   PRICE_SIMPL_,         //Simpl Price (OC/2)
+   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
+   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
+   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
+   PRICE_DEMARK_         //Demark Price
+  };
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum SmoothMethod - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//| Входные параметры индикатора                 |
+//+----------------------------------------------+
+input Smooth_Method XMA_Method=MODE_SMA_; //метод усреднения
+input uint XLength=12;                    //глубина сглаживания                    
+input int XPhase=15;                      //параметр сглаживания,
+//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
+input Applied_price_ IPC=PRICE_CLOSE_;    //ценовая константа
+input double Deviation=0.1;               // Девиация
+input uint Digit=2;                       //количество разрядов округления
+input int Shift=0;                        //сдвиг индикатора по горизонтали в барах
+input int PriceShift=0;                   //cдвиг индикатора по вертикали в пунктах
+input bool ShowPrice=true;                //показывать ценовые метки
+//---- цвета ценовых меток
+input color  Upper_color=clrMediumSeaGreen;
+input color  Lower_color=clrRed;
+//+----------------------------------------------+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double UpBuffer[],DnBuffer[],UpLineBuffer[],DnLineBuffer[];
+//---- Объявление переменных значения вертикального сдвига мувинга и коэффициентов девиации
+double dPriceShift,UpKdev,DnKdev,PointPow10;
+//---- Объявление целых переменных начала отсчёта данных
+int min_rates_total;
+//---- Объявление стрингов для текстовых меток
+string upper_name,lower_name;
+//+------------------------------------------------------------------+   
+//| Custom indicator initialization function                         | 
+//+------------------------------------------------------------------+ 
+void OnInit()
+  {
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_total=XMA1.GetStartBars(XMA_Method,XLength,XPhase);
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMALengthCheck("XLength",XLength);
+   XMA1.XMAPhaseCheck("XPhase",XPhase,XMA_Method);
+//---- Инициализация сдвига по вертикали
+   dPriceShift=_Point*PriceShift;
+//---- Инициализация коэффициента девиации  
+   UpKdev=(1+Deviation/100.0);
+   DnKdev=(1-Deviation/100.0);
+   PointPow10=_Point*MathPow(10,Digit);
+//---- Инициализация стрингов
+   upper_name="XEnvelopes upper text lable";
+   lower_name="XEnvelopes lower text lable";
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,UpBuffer,INDICATOR_DATA);
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(1,DnBuffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамических массивов в индикаторные буферы
+   SetIndexBuffer(2,UpLineBuffer,INDICATOR_DATA);
+   SetIndexBuffer(3,DnLineBuffer,INDICATOR_DATA);
+//---- установка позиции, с которой начинается отрисовка уровней
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,"Env("+string(XLength)+")");
+   PlotIndexSetString(0,PLOT_LABEL,"Env("+string(XLength)+")Cloud");
+   PlotIndexSetString(1,PLOT_LABEL,"Env("+string(XLength)+")Upper");
+   PlotIndexSetString(2,PLOT_LABEL,"Env("+string(XLength)+")Lower");
+
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
+//---- завершение инициализации
+  }
+//+------------------------------------------------------------------+
+//| Custom indicator deinitialization function                       |
+//+------------------------------------------------------------------+    
+void OnDeinit(const int reason)
+  {
+//----
+   ObjectDelete(0,upper_name);
+   ObjectDelete(0,lower_name);
+//----
+  }
+//+------------------------------------------------------------------+ 
+//| Custom indicator iteration function                              | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+
+//---- Объявление переменных с плавающей точкой  
+   double price,xma;
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int first,bar;
+
+//---- расчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=0; // стартовый номер для расчёта всех баров
+   else first=prev_calculated-1; // стартовый номер для расчёта новых баров
+
+//---- Основной цикл расчёта индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      price=PriceSeries(IPC,bar,open,low,high,close);
+      xma=XMA1.XMASeries(0,prev_calculated,rates_total,XMA_Method,XPhase,XLength,price,bar,false);      
+      UpBuffer[bar]=UpLineBuffer[bar]=PointPow10*MathCeil((UpKdev*xma)/PointPow10)+dPriceShift;
+      DnBuffer[bar]=DnLineBuffer[bar]=PointPow10*MathFloor((DnKdev*xma)/PointPow10)+dPriceShift;
+     }
+   if(ShowPrice)
+     {
+      int bar0=rates_total-1;
+      datetime time0=time[bar0]+Shift*PeriodSeconds();
+      SetRightPrice(0,upper_name,0,time0,UpBuffer[bar0],Upper_color);
+      SetRightPrice(0,lower_name,0,time0,DnBuffer[bar0],Lower_color);
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+
+//|  RightPrice creation                                             |
+//+------------------------------------------------------------------+
+void CreateRightPrice(long chart_id,// chart ID
+                      string   name,              // object name
+                      int      nwin,              // window index
+                      datetime time,              // price level time
+                      double   price,             // price level
+                      color    Color              // Text color
+                      )
+//---- 
+  {
+//----
+   ObjectCreate(chart_id,name,OBJ_ARROW_RIGHT_PRICE,nwin,time,price);
+   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
+   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);
+   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,2);
+//----
+  }
+//+------------------------------------------------------------------+
+//|  RightPrice reinstallation                                       |
+//+------------------------------------------------------------------+
+void SetRightPrice(long chart_id,// chart ID
+                   string   name,              // object name
+                   int      nwin,              // window index
+                   datetime time,              // price level time
+                   double   price,             // price level
+                   color    Color              // Text color
+                   )
+//---- 
+  {
+//----
+   if(ObjectFind(chart_id,name)==-1) CreateRightPrice(chart_id,name,nwin,time,price,Color);
+   else ObjectMove(chart_id,name,0,time,price);
+//----
+  }
+//+------------------------------------------------------------------+