Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

XDerivative_StDev_HTF - indicator for MetaTrader 5/README.md

@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `XDerivative_StDev.mq5`
+
+### Screenshots:
+![Screenshot](picture__22.png)
+
+> Made with ❤️ for the trading community.

XDerivative_StDev_HTF - indicator for MetaTrader 5/XDerivative_StDev.mq5

@@ -0,0 +1,303 @@
+//+---------------------------------------------------------------------+
+//|                                               XDerivative_StDev.mq5 | 
+//|                                  Copyright © 2015, Nikolay Kositsin | 
+//|                                 Khabarovsk,   farria@mail.redcom.ru | 
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2015, Nikolay Kositsin"
+#property link "farria@mail.redcom.ru"
+//---- номер версии индикатора
+#property version   "1.00"
+//---- отрисовка индикатора в отдельном окне
+#property indicator_separate_window
+//---- для расчёта и отрисовки индикатора использовано пять буферов
+#property indicator_buffers 5
+//---- использовано всего пять графических построений
+#property indicator_plots   5
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора              |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде линии
+#property indicator_type1   DRAW_LINE
+//---- в качестве цвета линии индикатора использован DodgerBlue цвет
+#property indicator_color1 clrDodgerBlue
+//---- линия индикатора - непрерывная кривая
+#property indicator_style1  STYLE_SOLID
+//---- толщина линии индикатора равна 2
+#property indicator_width1  2
+//---- отображение метки индикатора
+#property indicator_label1  "XDerivative"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 2 в виде символа
+#property indicator_type2   DRAW_ARROW
+//---- в качестве цвета медвежьего индикатора использован красный цвет
+#property indicator_color2  clrRed
+//---- толщина линии индикатора 2 равна 2
+#property indicator_width2  2
+//---- отображение медвежьей метки индикатора
+#property indicator_label2  "Dn_Signal 1"
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//---- отрисовка индикатора 3 в виде символа
+#property indicator_type3   DRAW_ARROW
+//---- в качестве цвета бычьего индикатора использован салатовый цвет
+#property indicator_color3  clrSpringGreen
+//---- толщина линии индикатора 3 равна 2
+#property indicator_width3  2
+//---- отображение бычей метки индикатора
+#property indicator_label3  "Up_Signal 1"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 4 в виде символа
+#property indicator_type4   DRAW_ARROW
+//---- в качестве цвета медвежьего индикатора использован красный цвет
+#property indicator_color4  clrRed
+//---- толщина линии индикатора 4 равна 4
+#property indicator_width4  4
+//---- отображение медвежьей метки индикатора
+#property indicator_label4  "Dn_Signal 2"
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//---- отрисовка индикатора 5 в виде символа
+#property indicator_type5   DRAW_ARROW
+//---- в качестве цвета бычьего индикатора использован салатовый цвет
+#property indicator_color5  clrSpringGreen
+//---- толщина линии индикатора 5 равна 4
+#property indicator_width5  4
+//---- отображение бычей метки индикатора
+#property indicator_label5  "Up_Signal 2"
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+enum ENUM_PRICE_TYPE //Тип константы
+  {
+   PRICE_CLOSE_ = 1,     //Close
+   PRICE_OPEN_,          //Open
+   PRICE_HIGH_,          //High
+   PRICE_LOW_,           //Low
+   PRICE_MEDIAN_,        //Median Price (HL/2)
+   PRICE_TYPICAL_,       //Typical Price (HLC/3)
+   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
+   PRICE_SIMPL_,         //Simpl Price (OC/2)
+   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
+   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
+   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
+   PRICE_DEMARK_         //Demark Price
+  };
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input uint  i_slowing = 34; // Slowing / Запаздывание
+input ENUM_PRICE_TYPE i_price = PRICE_WEIGHTED_; // Applied price / Используемая цена
+input Smooth_Method XMA_Method=MODE_JJMA; //метод усреднения
+input int XLength=7; //глубина сглаживания                    
+input int XPhase=15; //параметр сглаживания,
+//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
+input double dK1=1.5;  //коэффициент 1 для квадратичного фильтра
+input double dK2=2.5;  //коэффициент 2 для квадратичного фильтра
+input uint std_period=9; //период квадратичного фильтра
+input int Shift=0; // сдвиг индикатора по горизонтали в барах
+//+----------------------------------------------+
+
+//---- объявление динамического массива, который будет в 
+// дальнейшем использован в качестве индикаторного буфера
+double IndBuffer[];
+double BearsBuffer1[],BullsBuffer1[];
+double BearsBuffer2[],BullsBuffer2[];
+double DDer[];
+//---- Объявление целых переменных начала отсчёта данных
+int min_rates_1,min_rates_total;
+//+------------------------------------------------------------------+   
+//| XMA indicator initialization function                            | 
+//+------------------------------------------------------------------+ 
+void OnInit()
+  {
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_1=int(i_slowing);
+   min_rates_total=min_rates_1+GetStartBars(XMA_Method,XLength,XPhase)+int(std_period);
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMALengthCheck("XLength",XLength);
+   XMA1.XMAPhaseCheck("XPhase",XPhase,XMA_Method);
+//---- распределение памяти под массивы переменных  
+   ArrayResize(DDer,std_period);
+   
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,IndBuffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+   
+//---- превращение динамического массива BearsBuffer в индикаторный буфер
+   SetIndexBuffer(1,BearsBuffer1,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 2 по горизонтали
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(1,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамического массива BullsBuffer в индикаторный буфер
+   SetIndexBuffer(2,BullsBuffer1,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 3 по горизонтали
+   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(2,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамического массива BearsBuffer в индикаторный буфер
+   SetIndexBuffer(3,BearsBuffer2,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 2 по горизонтали
+   PlotIndexSetInteger(3,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(3,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(3,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамического массива BullsBuffer в индикаторный буфер
+   SetIndexBuffer(4,BullsBuffer2,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 3 по горизонтали
+   PlotIndexSetInteger(4,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(4,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(4,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(4,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+   
+//---- инициализации переменной для короткого имени индикатора
+   string shortname;
+   string Smooth1=XMA1.GetString_MA_Method(XMA_Method);
+   StringConcatenate(shortname,"XDerivative_StDev(",i_slowing,", ",XLength,", ",Smooth1,")");
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+   
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
+//---- завершение инициализации
+  }
+//+------------------------------------------------------------------+ 
+//| XMA iteration function                                           | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+
+//---- Объявление переменных с плавающей точкой  
+   double der,SMAdif,Sum,StDev,dstd,BEARS1,BULLS1,BEARS2,BULLS2,Filter1,Filter2;
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int first,bar;
+
+//---- расчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=min_rates_1; // стартовый номер для расчёта всех баров
+   else first=prev_calculated-1; // стартовый номер для расчёта новых баров
+
+//---- Основной цикл расчёта индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      der=100.0 *(PriceSeries(i_price,bar,open,low,high,close)-PriceSeries(i_price,bar-i_slowing,open,low,high,close))/i_slowing;
+      IndBuffer[bar]=XMA1.XMASeries(min_rates_1,prev_calculated,rates_total,XMA_Method,XPhase,XLength,der,bar,false);
+     }
+     
+     
+//---- пересчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=min_rates_total;
+//---- основной цикл расчёта индикатора стандартных отклонений
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      //---- загружаем приращения индикатора в массив для промежуточных вычислений
+      for(int iii=0; iii<int(std_period); iii++) DDer[iii]=IndBuffer[bar-iii]-IndBuffer[bar-iii-1];
+
+      //---- находим простое среднее приращений индикатора
+      Sum=0.0;
+      for(int iii=0; iii<int(std_period); iii++) Sum+=DDer[iii];
+      SMAdif=Sum/std_period;
+
+      //---- находим сумму квадратов разностей приращений и среднего
+      Sum=0.0;
+      for(int iii=0; iii<int(std_period); iii++) Sum+=MathPow(DDer[iii]-SMAdif,2);
+
+      //---- определяем итоговое значение среднеквадратичного отклонения StDev от приращения индикатора
+      StDev=MathSqrt(Sum/std_period);
+
+      //---- инициализация переменных
+      dstd=NormalizeDouble(DDer[0],_Digits+2);
+      Filter1=NormalizeDouble(dK1*StDev,_Digits+2);
+      Filter2=NormalizeDouble(dK2*StDev,_Digits+2);
+      BEARS1=EMPTY_VALUE;
+      BULLS1=EMPTY_VALUE;
+      BEARS2=EMPTY_VALUE;
+      BULLS2=EMPTY_VALUE;
+      der=IndBuffer[bar];
+
+      //---- вычисление индикаторных значений
+      if(dstd<-Filter1 && dstd>=-Filter2) BEARS1=der; //есть нисходящий тренд
+      if(dstd<-Filter2) BEARS2=der; //есть нисходящий тренд
+      if(dstd>+Filter1 && dstd<=+Filter2) BULLS1=der; //есть восходящий тренд
+      if(dstd>+Filter2) BULLS2=der; //есть восходящий тренд
+
+      //---- инициализация ячеек индикаторных буферов полученными значениями 
+      BullsBuffer1[bar]=BULLS1;
+      BearsBuffer1[bar]=BEARS1;
+      BullsBuffer2[bar]=BULLS2;
+      BearsBuffer2[bar]=BEARS2;
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+