Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

2025-06-24 00:50:24 +01:00
commit 884a002026
4971 changed files with 70275 additions and 0 deletions
@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `XDPO_Sign.mq5`
+
+### Screenshots:
+![Screenshot](picture__51.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,233 @@
+//+---------------------------------------------------------------------+
+//|                                                       XDPO_Sign.mq5 | 
+//|                                           Copyright © 2006, Ramdass | 
+//|                                                                     | 
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2006, Ramdass"
+#property link ""
+//---- номер версии индикатора
+#property version   "1.00"
+//--- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+//--- для расчета и отрисовки индикатора использовано два буфера
+#property indicator_buffers 2
+//--- использовано два графических построения
+#property indicator_plots   2
+//+----------------------------------------------+
+//|  Объявление констант                         |
+//+----------------------------------------------+
+#define RESET 0       // константа для возврата терминалу команды на пересчет индикатора
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//--- отрисовка индикатора 1 в виде символа
+#property indicator_type1   DRAW_ARROW
+//--- в качестве цвета медвежьей линии индикатора использован DeepPink цвет
+#property indicator_color1  clrDeepPink
+//--- толщина линии индикатора 1 равна 4
+#property indicator_width1  4
+//--- отображение бычей метки индикатора
+#property indicator_label1  "XDPO Sell"
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//--- отрисовка индикатора 2 в виде символа
+#property indicator_type2   DRAW_ARROW
+//--- в качестве цвета бычей линии индикатора использован DodgerBlue цвет
+#property indicator_color2  clrDodgerBlue
+//--- толщина линии индикатора 2 равна 4
+#property indicator_width2  4
+//--- отображение медвежьей метки индикатора
+#property indicator_label2 "XDPO Buy"
+
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1,XMA2;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+enum Applied_price_ //Тип константы
+  {
+   PRICE_CLOSE_ = 1,     //Close
+   PRICE_OPEN_,          //Open
+   PRICE_HIGH_,          //High
+   PRICE_LOW_,           //Low
+   PRICE_MEDIAN_,        //Median Price (HL/2)
+   PRICE_TYPICAL_,       //Typical Price (HLC/3)
+   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
+   PRICE_SIMPL_,         //Simpl Price (OC/2)
+   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
+   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
+   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
+   PRICE_DEMARK_         //Demark Price
+  };
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input Smooth_Method MA_Method1=MODE_SMA_; //Метод усреднения цены
+input int Length1=12; //Глубина усреднения цены                   
+input int Phase1=15; //Параметр усреднения цены,
+                     //для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+// Для VIDIA это период CMO, для AMA это период медленной скользящей
+input Smooth_Method MA_Method2=MODE_JJMA; //Метод сглаживания 
+input int Length2= 5; //Глубина сглаживания 
+input int Phase2=15;  //Параметр сглаживания,
+                      //для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+// Для VIDIA это период CMO, для AMA это период медленной скользящей
+input Applied_price_ IPC=PRICE_CLOSE_;//Ценовая константа
+input int Shift=0; // Сдвиг индикатора по горизонтали в барах
+//+----------------------------------------------+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double SellBuffer[],BuyBuffer[];
+//---- объявление целочисленных переменных для хендлов индикаторов
+int ATR_Handle;
+//---- Объявление целых переменных начала отсчета данных
+int min_rates_total,min_rates_1,min_rates_2;
+//+------------------------------------------------------------------+   
+//| XDPO indicator initialization function                           | 
+//+------------------------------------------------------------------+ 
+int OnInit()
+  {
+//---- Инициализация переменных начала отсчета данных
+   min_rates_1=XMA1.GetStartBars(MA_Method1, Length1, Phase1);
+   min_rates_2=XMA2.GetStartBars(MA_Method2, Length2, Phase2);
+   min_rates_total=min_rates_1+min_rates_2+1;
+   int ATR_Period=10;
+   min_rates_total=int(MathMax(min_rates_total,ATR_Period));
+//---- получение хендла индикатора ATR
+   ATR_Handle=iATR(NULL,0,ATR_Period);
+   if(ATR_Handle==INVALID_HANDLE)
+     {
+      Print(" Не удалось получить хендл индикатора ATR");
+      return(INIT_FAILED);
+     }
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMALengthCheck("Length1", Length1);
+   XMA2.XMALengthCheck("Length2", Length2);
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMAPhaseCheck("Phase1", Phase1, MA_Method1);
+   XMA2.XMAPhaseCheck("Phase2", Phase2, MA_Method2);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,SellBuffer,INDICATOR_DATA);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 1
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- символ для индикатора
+   PlotIndexSetInteger(0,PLOT_ARROW,172);
+//---- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(1,BuyBuffer,INDICATOR_DATA);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 2
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//---- символ для индикатора
+   PlotIndexSetInteger(1,PLOT_ARROW,172);
+//---- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+
+//---- инициализации переменной для короткого имени индикатора
+   string shortname;
+   string Smooth1=XMA1.GetString_MA_Method(MA_Method1);
+   string Smooth2=XMA1.GetString_MA_Method(MA_Method2);
+   StringConcatenate(shortname,"XDPO_Histogram(",Length1,", ",Length2,", ",Smooth1,", ",Smooth2,")");
+//---- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+
+//---- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
+//--- завершение инициализации
+   return(INIT_SUCCEEDED);
+  }
+//+------------------------------------------------------------------+ 
+//| XDPO iteration function                                          | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[])
+  {
+//---- проверка количества баров на достаточность для расчета
+   if(BarsCalculated(ATR_Handle)<rates_total || rates_total<min_rates_total) return(RESET);
+
+//---- Объявление переменных с плавающей точкой  
+   double price,x1xma,diff,xdiff,ATR[1];
+   static double xdiff_prev,xdiff_prev_prev;
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int first,bar;
+
+//---- расчет стартового номера first для цикла пересчета баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчета индикатора
+     {
+      first=0; // стартовый номер для расчета всех баров
+      xdiff_prev=0.0;
+      xdiff_prev_prev=0.0;
+     }
+   else first=prev_calculated-1; // стартовый номер для расчета новых баров
+
+//---- Основной цикл расчета индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      price=PriceSeries(IPC,bar,open,low,high,close);
+      x1xma= XMA1.XMASeries(0,prev_calculated,rates_total,MA_Method1,Phase1,Length1,price,bar,false);
+      diff=price-x1xma;
+      xdiff=XMA2.XMASeries(min_rates_1,prev_calculated,rates_total,MA_Method2,Phase2,Length2,diff,bar,false);
+      
+      BuyBuffer[bar]=0.0;
+      SellBuffer[bar]=0.0;
+
+      if(xdiff_prev_prev>xdiff_prev && xdiff_prev<xdiff)
+        {
+         //---- копируем вновь появившиеся данные в массив
+         if(CopyBuffer(ATR_Handle,0,time[bar],1,ATR)<=0) return(RESET);
+         BuyBuffer[bar]=low[bar]-ATR[0]*3/8;
+        }
+        
+      if(xdiff_prev_prev<xdiff_prev && xdiff_prev>xdiff)
+        {
+         //---- копируем вновь появившиеся данные в массив
+         if(CopyBuffer(ATR_Handle,0,time[bar],1,ATR)<=0) return(RESET);
+         SellBuffer[bar]=high[bar]+ATR[0]*3/8;
+        }
+
+      if(bar<rates_total-1)
+        {
+         xdiff_prev_prev=xdiff_prev;
+         xdiff_prev=xdiff;
+        }
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+