Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

XChannel_HTF - indicator for MetaTrader 5/README.md

@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `XChannel.mq5`
+
+### Screenshots:
+![Screenshot](picture__68.png)
+
+> Made with ❤️ for the trading community.

XChannel_HTF - indicator for MetaTrader 5/XChannel.mq5

@@ -0,0 +1,150 @@
+//+---------------------------------------------------------------------+
+//|                                                        XChannel.mq5 | 
+//|                                               Copyright © 2006, Gep | 
+//|                                                                     | 
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2006, Gep"
+#property link ""
+//---- номер версии индикатора
+#property version   "1.01"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+//---- количество индикаторных буферов 2
+#property indicator_buffers 2 
+//---- использовано всего одно графическое построение
+#property indicator_plots   1
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора 1            |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде цветного облака
+#property indicator_type1   DRAW_FILLING
+//---- в качестве цвета индикатора использован
+#property indicator_color1  clrYellow
+//---- отображение метки индикатора
+#property indicator_label1 "Up;Down"
+
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1,XMA2;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input Smooth_Method XMA_Method=MODE_SMA_; //метод усреднения
+input uint XLength=20; //глубина усреднения                    
+input int XPhase=15; //параметр усреднения,
+  //для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+  // Для VIDIA это период CMO, для AMA это период медленной скользящей
+input int Delta=100;  //смещение каналов по вертикали в пунктах
+input int Shift=0; // сдвиг индикатора по горизонтали в барах
+//+----------------------------------------------+
+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double UpIndBuffer[];
+double DnIndBuffer[];
+//----
+double dDelta;
+//---- Объявление целых переменных начала отсчёта данных
+int min_rates_total;
+//+------------------------------------------------------------------+   
+//| XChannel indicator initialization function                       | 
+//+------------------------------------------------------------------+ 
+void OnInit()
+  {
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_total=XMA1.GetStartBars(XMA_Method,XLength,XPhase);
+   dDelta=Delta*_Point;
+   
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMALengthCheck("XLength", XLength);
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMAPhaseCheck("XPhase", XPhase, XMA_Method);
+   
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,UpIndBuffer,INDICATOR_DATA);
+   SetIndexBuffer(1,DnIndBuffer,INDICATOR_DATA);
+
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
+//---- осуществление сдвига индикатора по горизонтали на Shift
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+   
+//---- инициализации переменной для короткого имени индикатора
+   string shortname;
+   string Smooth=XMA1.GetString_MA_Method(XMA_Method);
+   StringConcatenate(shortname,"XChannel(",XLength,", ",Smooth,", ",Delta,")");
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+   
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
+//---- завершение инициализации
+  }
+//+------------------------------------------------------------------+ 
+//| XChannel iteration function                                      | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+
+//---- Объявление переменных с плавающей точкой  
+   double upxma,dnxma;
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int first,bar;
+
+//---- расчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=0; // стартовый номер для расчёта всех баров
+   else first=prev_calculated-1; // стартовый номер для расчёта новых баров
+
+//---- Основной цикл расчёта индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     { 
+      upxma=XMA1.XMASeries(0,prev_calculated,rates_total,XMA_Method,XPhase,XLength,high[bar],bar,false);
+      dnxma=XMA2.XMASeries(0,prev_calculated,rates_total,XMA_Method,XPhase,XLength,low[bar],bar,false);
+      //----       
+      UpIndBuffer[bar]=upxma+dDelta;
+      DnIndBuffer[bar]=dnxma-dDelta;
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+