Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

X2MA_StDev_HTF - indicator for MetaTrader 5/README.md

@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `X2MA_StDev.mq5`
+
+### Screenshots:
+![Screenshot](picture__23.png)
+
+> Made with ❤️ for the trading community.

X2MA_StDev_HTF - indicator for MetaTrader 5/X2MA_StDev.mq5

@@ -0,0 +1,284 @@
+//+---------------------------------------------------------------------+
+//|                                                      X2MA_StDev.mq5 | 
+//|                                  Copyright © 2011, Nikolay Kositsin | 
+//|                                 Khabarovsk,   farria@mail.redcom.ru | 
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2011, Nikolay Kositsin"
+#property link "farria@mail.redcom.ru"
+//---- номер версии индикатора
+#property version   "1.02"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+//---- для расчёта и отрисовки индикатора использовано четыре буфера
+#property indicator_buffers 4
+//---- использовано три графических построения
+#property indicator_plots   3
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора              |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде многоцветной линии
+#property indicator_type1   DRAW_COLOR_LINE
+//---- в качестве цветов трехцветной линии использованы
+#property indicator_color1  clrGray,clrBlueViolet,clrMagenta
+//---- линия индикатора - непрерывная кривая
+#property indicator_style1  STYLE_SOLID
+//---- толщина линии индикатора равна 2
+#property indicator_width1  2
+//---- отображение метки индикатора
+#property indicator_label1  "X2MA"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 2 в виде символа
+#property indicator_type2   DRAW_ARROW
+//---- в качестве цвета медвежьего индикатора использован красный цвет
+#property indicator_color2  clrRed
+//---- толщина линии индикатора 2 равна 2
+#property indicator_width2  2
+//---- отображение медвежьей метки индикатора
+#property indicator_label2  "Dn_Signal"
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//---- отрисовка индикатора 3 в виде символа
+#property indicator_type3   DRAW_ARROW
+//---- в качестве цвета бычьего индикатора использован зелёный цвет
+#property indicator_color3  clrLime
+//---- толщина линии индикатора 3 равна 2
+#property indicator_width3  2
+//---- отображение бычей метки индикатора
+#property indicator_label3  "Up_Signal"
+
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1,XMA2;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+enum Applied_price_ //Тип константы
+  {
+   PRICE_CLOSE_ = 1,     //Close
+   PRICE_OPEN_,          //Open
+   PRICE_HIGH_,          //High
+   PRICE_LOW_,           //Low
+   PRICE_MEDIAN_,        //Median Price (HL/2)
+   PRICE_TYPICAL_,       //Typical Price (HLC/3)
+   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
+   PRICE_SIMPL_,         //Simpl Price (OC/2)
+   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
+   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
+   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
+   PRICE_DEMARK_         //Demark Price
+  };
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input Smooth_Method MA_Method1=MODE_SMA; //Метод усреднения первого сглаживания 
+input uint Length1=12; //Глубина  первого сглаживания                    
+input int Phase1=15; //Параметр первого сглаживания,
+  //для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+  // Для VIDIA это период CMO, для AMA это период медленной скользящей
+input Smooth_Method MA_Method2=MODE_JJMA; //Метод усреднения второго сглаживания 
+input uint Length2 = 5; //Глубина  второго сглаживания 
+input int Phase2=15;  //Параметр второго сглаживания,
+  //для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+  // Для VIDIA это период CMO, для AMA это период медленной скользящей
+input Applied_price_ IPC=PRICE_CLOSE;//Ценовая константа
+input double dK=2.0;  //коэффициент для квадратичного фильтра
+input uint std_period=9; //период квадратичного фильтра
+input int Shift=0; // Сдвиг индикатора по горизонтали в барах
+input int PriceShift=0; // Сдвиг индикатора по вертикали в пунктах
+//+----------------------------------------------+
+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double X2MABuffer[];
+double ColorX2MABuffer[];
+double BearsBuffer[];
+double BullsBuffer[];
+
+double dX2MA[];
+//---- Объявление переменной значения вертикального сдвига мувинга
+double dPriceShift;
+//---- Объявление целых переменных начала отсчета данных
+int min_rates_total,min_rates_1,min_rates_2;
+//+------------------------------------------------------------------+   
+//| X2MA indicator initialization function                           | 
+//+------------------------------------------------------------------+ 
+void OnInit()
+  {
+//---- Инициализация переменных начала отсчета данных
+   min_rates_1=XMA1.GetStartBars(MA_Method1,Length1,Phase1);
+   min_rates_2=XMA2.GetStartBars(MA_Method2,Length2,Phase2);
+   min_rates_total=min_rates_1+min_rates_2+1+int(std_period);
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMALengthCheck("Length1",Length1);
+   XMA2.XMALengthCheck("Length2",Length2);
+//---- установка алертов на недопустимые значения внешних переменных
+   XMA1.XMAPhaseCheck("Phase1",Phase1,MA_Method1);
+   XMA2.XMAPhaseCheck("Phase2",Phase2,MA_Method2);
+   
+//---- Инициализация сдвига по вертикали
+   dPriceShift=_Point*PriceShift;
+   
+//---- Распределение памяти под массивы переменных  
+   ArrayResize(dX2MA,std_period);
+   
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,X2MABuffer,INDICATOR_DATA);
+//---- превращение динамического массива в цветовой, индексный буфер   
+   SetIndexBuffer(1,ColorX2MABuffer,INDICATOR_COLOR_INDEX);
+   
+//---- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчета отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
+   
+//---- превращение динамического массива BearsBuffer в индикаторный буфер
+   SetIndexBuffer(2,BearsBuffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 2 по горизонтали на std_shift
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 2 на std_period + 2
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(1,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);
+
+//---- превращение динамического массива BullsBuffer в индикаторный буфер
+   SetIndexBuffer(3,BullsBuffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 3 по горизонтали на std_shift
+   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 3 на std_period + 2
+   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(2,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,0.0);
+      
+//---- инициализации переменной для короткого имени индикатора
+   string shortname;
+   string Smooth1=XMA1.GetString_MA_Method(MA_Method1);
+   string Smooth2=XMA1.GetString_MA_Method(MA_Method2);
+   StringConcatenate(shortname,"X2MA(",Length1,", ",Length2,", ",Smooth1,", ",Smooth2,")");
+//---- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+   
+//---- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
+//---- завершение инициализации
+  }
+//+------------------------------------------------------------------+ 
+//| X2MA iteration function                                          | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[])
+  {
+//---- проверка количества баров на достаточность для расчета
+   if(rates_total<min_rates_total) return(0);
+
+//---- Объявление переменных с плавающей точкой  
+   double price,x1xma,x2xma,SMAdif,Sum,StDev,dstd,BEARS,BULLS,Filter;
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int first,bar;
+
+//---- расчет стартового номера first для цикла пересчета баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчета индикатора
+      first=0; // стартовый номер для расчета всех баров
+   else first=prev_calculated-1; // стартовый номер для расчета новых баров
+
+//---- Основной цикл расчета индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      //---- Вызов функции PriceSeries для получения входной цены price
+      price=PriceSeries(IPC,bar,open,low,high,close);
+
+      //---- Два вызова функции XMASeries. 
+      //Во втором вызове параметр begin увеличен на min_rates_1 т. к. это повторное XMA сглаживание  
+      x1xma = XMA1.XMASeries(0,prev_calculated,rates_total,MA_Method1,Phase1,Length1,price,bar,false);
+      x2xma = XMA2.XMASeries(min_rates_1,prev_calculated,rates_total,MA_Method2, Phase2, Length2,x1xma,bar,false);
+      X2MABuffer[bar]=x2xma+dPriceShift;
+     }
+
+//---- корректировка значения переменной first
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчета индикатора
+      first=min_rates_total; // стартовый номер для расчета всех баров
+           
+//---- Основной цикл раскраски сигнальной линии
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      ColorX2MABuffer[bar]=0;
+      if(X2MABuffer[bar-1]<X2MABuffer[bar]) ColorX2MABuffer[bar]=1;
+      if(X2MABuffer[bar-1]>X2MABuffer[bar]) ColorX2MABuffer[bar]=2;
+     }
+
+//---- основной цикл расчёта индикатора стандартных отклонений
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      //---- загружаем приращения индикатора в массив для промежуточных вычислений
+      for(int iii=0; iii<int(std_period); iii++) dX2MA[iii]=X2MABuffer[bar-iii-0]-X2MABuffer[bar-iii-1];
+
+      //---- находим простое среднее приращений индикатора
+      Sum=0.0;
+      for(int iii=0; iii<int(std_period); iii++) Sum+=dX2MA[iii];
+      SMAdif=Sum/std_period;
+
+      //---- находим сумму квадратов разностей приращений и среднего
+      Sum=0.0;
+      for(int iii=0; iii<int(std_period); iii++) Sum+=MathPow(dX2MA[iii]-SMAdif,2);
+
+      //---- определяем итоговое значение среднеквадратичного отклонения StDev от приращения индикатора
+      StDev=MathSqrt(Sum/std_period);
+
+      //---- инициализация переменных
+      dstd=NormalizeDouble(dX2MA[0],_Digits+2);
+      Filter=NormalizeDouble(dK*StDev,_Digits+2);
+      BEARS=0;
+      BULLS=0;
+
+      //---- вычисление индикаторных значений
+      if(dstd<-Filter) BEARS=X2MABuffer[bar]; //есть нисходящий тренд
+      if(dstd>+Filter) BULLS=X2MABuffer[bar]; //есть восходящий тренд
+
+      //---- инициализация ячеек индикаторных буферов полученными значениями 
+      BullsBuffer[bar]=BULLS;
+      BearsBuffer[bar]=BEARS;
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+