Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 4

2025-06-24 00:50:24 +01:00
commit 884a002026
4971 changed files with 70275 additions and 0 deletions
@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `WPR_Chart.mq5`
+
+### Screenshots:
+![Screenshot](picture__78.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,239 @@
+//+---------------------------------------------------------------------+
+//|                                                       WPR_Chart.mq5 | 
+//|                                Copyright © 2015, Yuriy Tokman (YTG) |
+//|                                                  http://ytg.com.ua/ |
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2015, Yuriy Tokman (YTG)"
+#property link      "http://ytg.com.ua/"
+#property description "Индикатор WPR на ценовом графике"
+//---- номер версии индикатора
+#property version   "1.00"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+//---- количество индикаторных буферов 4
+#property indicator_buffers 4 
+//---- использовано всего три графических построения
+#property indicator_plots   3
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора  WPR Cloud   |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде облака
+#property indicator_type1   DRAW_FILLING
+//---- в качестве цветов облака индикатора использованы
+#property indicator_color1  clrLavender
+//---- отображение метки индикатора
+#property indicator_label1  "WPR Cloud"
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора XMA          |
+//+----------------------------------------------+
+//---- отрисовка индикатора 2 в виде линии
+#property indicator_type2   DRAW_LINE
+//---- в качестве цвета линии индикатора использован цвет HotPink
+#property indicator_color2  clrHotPink
+//---- линия индикатора 2 - непрерывная кривая
+#property indicator_style2  STYLE_SOLID
+//---- толщина линии индикатора 2 равна 2
+#property indicator_width2  2
+//---- отображение метки индикатора
+#property indicator_label2  "XMA"
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора WPR          |
+//+----------------------------------------------+
+//---- отрисовка индикатора 3 в виде линии
+#property indicator_type3   DRAW_LINE
+//---- в качестве цвета линии индикатора использован цвет BlueViolet
+#property indicator_color3  clrBlueViolet
+//---- линия индикатора 3 - непрерывная кривая
+#property indicator_style3  STYLE_SOLID
+//---- толщина линии индикатора 3 равна 2
+#property indicator_width3  2
+//---- отображение метки индикатора
+#property indicator_label3  "WPR"
+//+----------------------------------------------+
+//|  объявление констант                         |
+//+----------------------------------------------+
+#define RESET 0                // Константа для возврата терминалу команды на пересчет индикатора
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+enum Applied_price_ //Тип константы
+  {
+   PRICE_CLOSE_ = 1,     //Close
+   PRICE_OPEN_,          //Open
+   PRICE_HIGH_,          //High
+   PRICE_LOW_,           //Low
+   PRICE_MEDIAN_,        //Median Price (HL/2)
+   PRICE_TYPICAL_,       //Typical Price (HLC/3)
+   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
+   PRICE_SIMPL_,         //Simpl Price (OC/2)
+   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
+   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
+   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
+   PRICE_DEMARK_         //Demark Price
+  };
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//| Входные параметры индикатора                 |
+//+----------------------------------------------+
+input uint PeriodWPR=14;                              // Период индикатора WPR
+input Smooth_Method XMA_Method=MODE_SMMA_;            // метод усреднения
+input uint XLength=12;                                // глубина  усреднения                    
+input int XPhase=15;                                  // параметр сглаживания,
+//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
+input double Dev=10.0;                                // Девиация ширины канала
+input Applied_price_  Applied_price=PRICE_CLOSE_;     // тип цены или handle
+input int  Level_WPR_UP = -40;                        // уровень перекупленности
+input int  Level_WPR_DN = -60;                        // уровень перепроданности
+input int Shift=0;                                    // Сдвиг индикатора по горизонтали в барах  
+//+----------------------------------------------+
+//---- объявление динамических массивов, которые в дальнейшем
+//---- будут использованы в качестве индикаторных буферов
+double Line1Buffer[];
+double Line2Buffer[];
+double Line3Buffer[];
+double Line4Buffer[];
+
+double dLevel_WPR_UP,dLevel_WPR_DN;
+//---- объявление целочисленных переменных начала отсчета данных
+int min_rates_total,min_rates_1;
+//--- объявление целочисленных переменных для хендлов индикаторов
+int Ind_Handle;
+//+------------------------------------------------------------------+
+//| Custom indicator initialization function                         |
+//+------------------------------------------------------------------+  
+int OnInit()
+  {
+//---- инициализация переменных начала отсчета данных
+   min_rates_1=int(PeriodWPR);
+   min_rates_total=min_rates_1+GetStartBars(XMA_Method,XLength,XPhase);
+
+   dLevel_WPR_UP=int(Level_WPR_UP+50)*_Point*Dev;
+   dLevel_WPR_DN=int(Level_WPR_DN+50)*_Point*Dev;
+
+//--- получение хендла индикатора WPR
+   Ind_Handle=iWPR(Symbol(),NULL,PeriodWPR);
+   if(Ind_Handle==INVALID_HANDLE)
+     {
+      Print("Не удалось получить хендл индикатора WPR");
+      return(INIT_FAILED);
+     }
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,Line1Buffer,INDICATOR_DATA);
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(1,Line2Buffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 1 по горизонтали на Shift
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчета отрисовки индикатора 1 на min_rates_total
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(2,Line3Buffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 2 по горизонтали на Shift
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчета отрисовки индикатора 2 на min_rates_total
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(3,Line4Buffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 3 по горизонтали на Shift
+   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчета отрисовки индикатора 3 на min_rates_total
+   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
+
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(Line1Buffer,true);
+   ArraySetAsSeries(Line2Buffer,true);
+   ArraySetAsSeries(Line3Buffer,true);
+   ArraySetAsSeries(Line4Buffer,true);
+
+//---- инициализации переменной для короткого имени индикатора
+   string shortname;
+   StringConcatenate(shortname,"F_WPR(",PeriodWPR,")");
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
+//---- завершение инициализации
+   return(INIT_SUCCEEDED);
+  }
+//+------------------------------------------------------------------+
+//| Custom indicator iteration function                              |
+//+------------------------------------------------------------------+
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(BarsCalculated(Ind_Handle)<rates_total || rates_total<min_rates_total) return(RESET);
+
+//---- Объявление переменных с плавающей точкой  
+   double price,xma,WPR[];
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int to_copy,limit,bar,maxbar=rates_total-1-min_rates_1;
+//---- расчет стартового номера limit для цикла пересчета баров
+   if(prev_calculated>rates_total || prev_calculated<=0)// проверка на первый старт расчета индикатора
+     {
+      limit=maxbar; // стартовый номер для расчета всех баров
+     }
+   else limit=rates_total-prev_calculated; // стартовый номер для расчета новых баров
+
+   to_copy=limit+1;
+//---- копируем вновь появившиеся данные в массивы
+   if(CopyBuffer(Ind_Handle,MAIN_LINE,0,to_copy,WPR)<=0) return(RESET);
+//---- индексация элементов в массиве как в таймсерии
+   ArraySetAsSeries(WPR,true);
+   ArraySetAsSeries(open,true);
+   ArraySetAsSeries(low,true);
+   ArraySetAsSeries(high,true);
+   ArraySetAsSeries(close,true);
+
+//---- Основной цикл расчёта индикатора
+   for(bar=limit; bar>=0 && !IsStopped(); bar--)
+     {
+      price=PriceSeries(Applied_price,bar,open,low,high,close);
+      xma=XMA1.XMASeries(maxbar,prev_calculated,rates_total,XMA_Method,XPhase,XLength,price,bar,true);
+      Line3Buffer[bar]=xma;
+      Line4Buffer[bar]=xma+Dev*(WPR[bar]+50)*_Point;
+      Line1Buffer[bar]=xma+dLevel_WPR_UP;
+      Line2Buffer[bar]=xma+dLevel_WPR_DN;
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+