121 lines
9.1 KiB
Plaintext
121 lines
9.1 KiB
Plaintext
//+------------------------------------------------------------------+
|
|
//| PR.mq5 |
|
|
//| Copyright 2018, MetaQuotes Software Corp. |
|
|
//| https://mql5.com |
|
|
//+------------------------------------------------------------------+
|
|
#property copyright "Copyright 2018, MetaQuotes Software Corp."
|
|
#property link "https://mql5.com"
|
|
#property version "1.00"
|
|
#property description "Period Range"
|
|
#property indicator_separate_window
|
|
#property indicator_buffers 1
|
|
#property indicator_plots 1
|
|
//--- plot Range
|
|
#property indicator_label1 "Range"
|
|
#property indicator_type1 DRAW_LINE
|
|
#property indicator_color1 clrDodgerBlue
|
|
#property indicator_style1 STYLE_SOLID
|
|
#property indicator_width1 1
|
|
//--- input parameters
|
|
input uint InpPeriod = 14; // Period
|
|
input bool InpUseLastPeriod = false; // Use last period
|
|
//--- indicator buffers
|
|
double BufferCentral[];
|
|
//--- global variables
|
|
int period;
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator initialization function |
|
|
//+------------------------------------------------------------------+
|
|
int OnInit()
|
|
{
|
|
//--- set global variables
|
|
period=int(InpPeriod<1 ? 1 : InpPeriod);
|
|
//--- indicator buffers mapping
|
|
SetIndexBuffer(0,BufferCentral,INDICATOR_DATA);
|
|
//--- setting indicator parameters
|
|
IndicatorSetString(INDICATOR_SHORTNAME,"PR("+(string)period+")");
|
|
IndicatorSetInteger(INDICATOR_DIGITS,Digits());
|
|
IndicatorSetInteger(INDICATOR_LEVELS,1);
|
|
IndicatorSetDouble(INDICATOR_LEVELVALUE,0,100);
|
|
//--- setting buffer arrays as timeseries
|
|
ArraySetAsSeries(BufferCentral,true);
|
|
//---
|
|
return(INIT_SUCCEEDED);
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator iteration function |
|
|
//+------------------------------------------------------------------+
|
|
int OnCalculate(const int rates_total,
|
|
const int prev_calculated,
|
|
const datetime &time[],
|
|
const double &open[],
|
|
const double &high[],
|
|
const double &low[],
|
|
const double &close[],
|
|
const long &tick_volume[],
|
|
const long &volume[],
|
|
const int &spread[])
|
|
{
|
|
//--- Проверка на минимальное колиество баров для расчёта
|
|
if(rates_total<period) return 0;
|
|
//--- Установка массивов буферов как таймсерий
|
|
ArraySetAsSeries(high,true);
|
|
ArraySetAsSeries(low,true);
|
|
ArraySetAsSeries(close,true);
|
|
//--- Проверка и расчёт количества просчитываемых баров
|
|
int limit=rates_total-prev_calculated;
|
|
if(limit>1)
|
|
{
|
|
limit=rates_total-period-2;
|
|
ArrayInitialize(BufferCentral,EMPTY_VALUE);
|
|
}
|
|
//--- Расчёт индикатора
|
|
double min=0,max=0;
|
|
for(int i=limit; i>=0 && !IsStopped(); i--)
|
|
{
|
|
if(InpUseLastPeriod)
|
|
{
|
|
int lb=Lowest(period,i);
|
|
int hb=Highest(period,i);
|
|
if(lb==WRONG_VALUE || hb==WRONG_VALUE) return 0;
|
|
min=low[lb];
|
|
max=high[hb];
|
|
}
|
|
else
|
|
{
|
|
int lb=Lowest(period,i+1);
|
|
int hb=Highest(period,i+1);
|
|
if(lb==WRONG_VALUE || hb==WRONG_VALUE) return 0;
|
|
min=low[lb];
|
|
max=high[hb];
|
|
}
|
|
BufferCentral[i]=(min!=max ? 100*(close[i]-min)/(max-min) : EMPTY_VALUE);
|
|
}
|
|
|
|
//--- return value of prev_calculated for next call
|
|
return(rates_total);
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Возвращает индекс максимального значения таймсерии high |
|
|
//+------------------------------------------------------------------+
|
|
int Highest(const int count,const int start)
|
|
{
|
|
double array[];
|
|
ArraySetAsSeries(array,true);
|
|
if(CopyHigh(Symbol(),PERIOD_CURRENT,start,count,array)==count)
|
|
return ArrayMaximum(array)+start;
|
|
return WRONG_VALUE;
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Возвращает индекс минимального значения таймсерии low |
|
|
//+------------------------------------------------------------------+
|
|
int Lowest(const int count,const int start)
|
|
{
|
|
double array[];
|
|
ArraySetAsSeries(array,true);
|
|
if(CopyLow(Symbol(),PERIOD_CURRENT,start,count,array)==count)
|
|
return ArrayMinimum(array)+start;
|
|
return WRONG_VALUE;
|
|
}
|
|
//+------------------------------------------------------------------+
|