Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 3

2025-06-24 00:49:58 +01:00
commit ce28e11d35
5015 changed files with 75789 additions and 0 deletions
@@ -0,0 +1,22 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `pchannel3.mq5`
+
+### Screenshots:
+![Screenshot](picture__20.png)
+![Screenshot](script.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,158 @@
+//+------------------------------------------------------------------+
+//|                                                    PChannel3.mq5 |
+//|                                           Copyright © 2005, Xaoc |
+//|                                             http://forex.xcd.ru/ |
+//+------------------------------------------------------------------+
+#property copyright "Copyright © 2005, Xaoc"
+#property link      "http://forex.xcd.ru/"
+//---- номер версии индикатора
+#property version   "1.00"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+#property indicator_separate_window
+//--- для расчета и отрисовки индикатора использовано три буфера
+#property indicator_buffers 3
+//--- использовано три графических построения
+#property indicator_plots   3
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//---- отрисовка индикатора 1 в виде линии
+#property indicator_type1   DRAW_LINE
+//---- в качестве цвета бычей линии индикатора использован зелёный цвет
+#property indicator_color1  clrLimeGreen
+//---- линия индикатора 1 - непрерывная кривая
+#property indicator_style1  STYLE_SOLID
+//---- толщина линии индикатора 1 равна 2
+#property indicator_width1  2
+//---- отображение бычей метки индикатора
+#property indicator_label1  "TOPBAND"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 2 в виде линии
+#property indicator_type2   DRAW_LINE
+//---- в качестве цвета медвежьей линии индикатора использован синий цвет
+#property indicator_color2  clrBlue
+//---- линия индикатора 2 - непрерывная кривая
+#property indicator_style2  STYLE_SOLID
+//---- толщина линии индикатора 2 равна 2
+#property indicator_width2  2
+//---- отображение медвежьей метки индикатора
+#property indicator_label2  "MIDBAND"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 3 в виде линии
+#property indicator_type3   DRAW_LINE
+//---- в качестве цвета медвежьей линии индикатора использован красный цвет
+#property indicator_color3  clrRed
+//---- линия индикатора 3 - непрерывная кривая
+#property indicator_style3  STYLE_SOLID
+//---- толщина линии индикатора 3 равна 2
+#property indicator_width3  2
+//---- отображение медвежьей метки индикатора
+#property indicator_label3  "BOTBAND"
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input uint   PCPeriod=55; 
+input int    Shift=0;     // Сдвиг индикатора по горизонтали в барах 
+//+----------------------------------------------+
+
+//---- Объявление целых переменных начала отсчёта данных
+int  min_rates_total;
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double ExtABuffer[];
+double ExtBBuffer[];
+double ExtCBuffer[];
+//+------------------------------------------------------------------+
+//| Custom indicator initialization function                         |
+//+------------------------------------------------------------------+
+void OnInit()
+  {
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_total=int(PCPeriod);
+   
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,ExtABuffer,INDICATOR_DATA);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+//---- осуществление сдвига индикатора по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(ExtABuffer,true);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(1,ExtBBuffer,INDICATOR_DATA);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+//---- осуществление сдвига индикатора по горизонтали
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(ExtBBuffer,true);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(2,ExtCBuffer,INDICATOR_DATA);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+//---- осуществление сдвига индикатора по горизонтали
+   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(ExtCBuffer,true);
+   
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,"PChannel3("+string(PCPeriod)+")");
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
+//---- завершение инициализации
+  }
+//+------------------------------------------------------------------+  
+//| Custom indicator iteration function                              | 
+//+------------------------------------------------------------------+  
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &Time[],
+                const double &Open[],
+                const double &High[],
+                const double &Low[],
+                const double &Close[],
+                const long &Tick_Volume[],
+                const long &Volume[],
+                const int &Spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+   
+//---- Объявление целых переменных
+   int limit;
+
+//---- расчёт стартового номера limit для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0)// проверка на первый старт расчёта индикатора
+        limit=rates_total-min_rates_total-1; // стартовый номер для расчёта всех баров
+   else limit=rates_total-prev_calculated;  // стартовый номер для расчёта только новых баров
+
+//---- индексация элементов в массивах как в таймсериях  
+   ArraySetAsSeries(High,true);
+   ArraySetAsSeries(Low,true);   
+   
+//---- основной цикл расчёта индикатора
+   for(int bar=limit; bar>=0 && !IsStopped(); bar--)
+     {
+      ExtABuffer[bar]=High[ArrayMaximum(High,bar,PCPeriod)];
+      ExtCBuffer[bar]=Low[ArrayMinimum(Low,bar,PCPeriod)];
+      ExtBBuffer[bar]=(ExtABuffer[bar]+ExtCBuffer[bar])/2.0;
+     }
+//----    
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+