Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 2

2025-06-24 00:49:28 +01:00
commit 3dac0b5f2f
5047 changed files with 75091 additions and 0 deletions
@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `finetuningma_stdev.mq5`
+
+### Screenshots:
+![Screenshot](picture__4.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,358 @@
+//+------------------------------------------------------------------+
+//|                                           FineTuningMA_StDev.mq5 | 
+//|                                         Copyright © 2010, gumgum |
+//|                                                                  |
+//+------------------------------------------------------------------+
+#property copyright "Copyright © 2010, gumgum"
+#property link      ""
+//---- номер версии индикатора
+#property version   "1.00"
+//---- описание индикатора
+#property description "Мувинг с более тонкой настройкой"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window 
+//---- для расчёта и отрисовки индикатора использовано пять буферов
+#property indicator_buffers 5
+//---- использовано всего пять графических построений
+#property indicator_plots   5
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора              |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде линии
+#property indicator_type1   DRAW_LINE
+//---- в качестве цвета линии индикатора использован RoyalBlue цвет
+#property indicator_color1 clrRoyalBlue
+//---- линия индикатора - непрерывная кривая
+#property indicator_style1  STYLE_SOLID
+//---- толщина линии индикатора равна 3
+#property indicator_width1  3
+//---- отображение метки индикатора
+#property indicator_label1  "FineTuningMA"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 2 в виде символа
+#property indicator_type2   DRAW_ARROW
+//---- в качестве цвета медвежьего индикатора использован красный цвет
+#property indicator_color2  clrRed
+//---- толщина линии индикатора 2 равна 2
+#property indicator_width2  2
+//---- отображение медвежьей метки индикатора
+#property indicator_label2  "Dn_Signal 1"
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//---- отрисовка индикатора 3 в виде символа
+#property indicator_type3   DRAW_ARROW
+//---- в качестве цвета бычьего индикатора использован салатовый цвет
+#property indicator_color3  clrSpringGreen
+//---- толщина линии индикатора 3 равна 2
+#property indicator_width3  2
+//---- отображение бычей метки индикатора
+#property indicator_label3  "Up_Signal 1"
+//+----------------------------------------------+
+//|  Параметры отрисовки медвежьего индикатора   |
+//+----------------------------------------------+
+//---- отрисовка индикатора 4 в виде символа
+#property indicator_type4   DRAW_ARROW
+//---- в качестве цвета медвежьего индикатора использован красный цвет
+#property indicator_color4  clrRed
+//---- толщина линии индикатора 4 равна 4
+#property indicator_width4  4
+//---- отображение медвежьей метки индикатора
+#property indicator_label4  "Dn_Signal 2"
+//+----------------------------------------------+
+//|  Параметры отрисовки бычьго индикатора       |
+//+----------------------------------------------+
+//---- отрисовка индикатора 5 в виде символа
+#property indicator_type5   DRAW_ARROW
+//---- в качестве цвета бычьего индикатора использован салатовый цвет
+#property indicator_color5  clrSpringGreen
+//---- толщина линии индикатора 5 равна 4
+#property indicator_width5  4
+//---- отображение бычей метки индикатора
+#property indicator_label5  "Up_Signal 2"
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+enum Applied_price_ //Тип константы
+  {
+   PRICE_CLOSE_ = 1,     //Close
+   PRICE_OPEN_,          //Open
+   PRICE_HIGH_,          //High
+   PRICE_LOW_,           //Low
+   PRICE_MEDIAN_,        //Median Price (HL/2)
+   PRICE_TYPICAL_,       //Typical Price (HLC/3)
+   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
+   PRICE_SIMPL_,         //Simpl Price (OC/2)
+   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
+   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
+   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price 
+   PRICE_DEMARK_         //Demark Price
+  };
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input uint   FTMA=10;
+input double rank1=2;
+input double rank2=2;
+input double rank3=2;
+input double shift1=1;
+input double shift2=1;
+input double shift3=1;
+input Applied_price_ IPC=PRICE_TYPICAL_;//ценовая константа
+  input double dK1=1.5;  //коэффициент 1 для квадратичного фильтра
+input double dK2=2.5;  //коэффициент 2 для квадратичного фильтра
+input uint std_period=9; //период квадратичного фильтра
+input int Shift=0; // сдвиг индикатора по горизонтали в барах
+input int PriceShift=0; // cдвиг индикатора по вертикали в пунктах
+//+----------------------------------------------+
+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double LineBuffer[];
+double BearsBuffer1[],BullsBuffer1[];
+double BearsBuffer2[],BullsBuffer2[];
+//----
+double PM[],dFTMA[];
+//---- Объявление переменной значения вертикального сдвига мувинга
+double dPriceShift;
+//---- Объявление целых переменных начала отсчёта данных
+int min_rates_total;
+//+------------------------------------------------------------------+   
+//| FineTuningMA indicator initialization function                   | 
+//+------------------------------------------------------------------+ 
+void OnInit()
+  {
+//---- Инициализация сдвига по вертикали
+   dPriceShift=_Point*PriceShift;
+
+//---- распределение памяти под массивы переменных  
+   ArrayResize(PM,FTMA); 
+   ArrayResize(dFTMA,std_period);
+
+//---- Инициализация переменных
+   double sum=0;
+   for(int h=0; h<int(FTMA); h++)
+     {
+      PM[h]=shift1+MathPow(h/(FTMA-1.0),rank1)*(1.0-shift1);
+      PM[h]=(shift2+MathPow(1-(h/(FTMA-1.0)),rank2)*(1.0-shift2))*PM[h];
+
+      if((h/(FTMA-1.))<0.5) PM[h]=(shift3+MathPow((1-(h/(FTMA-1.0))*2.0),rank3)*(1.0-shift3))*PM[h];
+      else PM[h]=(shift3+MathPow((h/(FTMA-1.0))*2.0-1.0,rank3)*(1.0-shift3))*PM[h];
+
+      sum+=PM[h];
+     }
+
+   double sum1=0;
+   for(int h=0; h<int(FTMA); h++)
+     {
+      PM[h]=PM[h]/sum;
+      sum1+=PM[h];
+     }
+
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_total=int(FTMA)+int(std_period);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,LineBuffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 1 по горизонтали
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
+   
+//---- превращение динамического массива BearsBuffer в индикаторный буфер
+   SetIndexBuffer(1,BearsBuffer1,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 2 по горизонтали
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(1,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамического массива BullsBuffer в индикаторный буфер
+   SetIndexBuffer(2,BullsBuffer1,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 3 по горизонтали
+   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(2,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамического массива BearsBuffer в индикаторный буфер
+   SetIndexBuffer(3,BearsBuffer2,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 2 по горизонтали
+   PlotIndexSetInteger(3,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(3,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(3,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//---- превращение динамического массива BullsBuffer в индикаторный буфер
+   SetIndexBuffer(4,BullsBuffer2,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 3 по горизонтали
+   PlotIndexSetInteger(4,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора
+   PlotIndexSetInteger(4,PLOT_DRAW_BEGIN,min_rates_total);
+//---- выбор символа для отрисовки
+   PlotIndexSetInteger(4,PLOT_ARROW,159);
+//---- запрет на отрисовку индикатором пустых значений
+   PlotIndexSetDouble(4,PLOT_EMPTY_VALUE,EMPTY_VALUE);
+
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,"FineTuningMA_StDev");
+
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
+//---- завершение инициализации
+  }
+//+------------------------------------------------------------------+ 
+//| FineTuningMA iteration function                                  | 
+//+------------------------------------------------------------------+ 
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+
+//---- Объявление целых переменных и получение уже посчитанных баров
+   int first,bar;
+   double ftma,SMAdif,Sum,StDev,dstd,BEARS1,BULLS1,BEARS2,BULLS2,Filter1,Filter2;
+
+//---- расчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=min_rates_total; // стартовый номер для расчёта всех баров
+   else first=prev_calculated-1; // стартовый номер для расчёта новых баров
+
+//---- Основной цикл расчёта индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      double sum1=0;
+      for(int h=0; h<int(FTMA); h++) sum1+=PM[h]*PriceSeries(IPC,bar-h,open,low,high,close);
+      LineBuffer[bar]=sum1+dPriceShift;
+     }
+     
+//---- пересчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=min_rates_total;
+//---- основной цикл расчёта индикатора стандартных отклонений
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      //---- загружаем приращения индикатора в массив для промежуточных вычислений
+      for(int iii=0; iii<int(std_period); iii++) dFTMA[iii]=LineBuffer[bar-iii]-LineBuffer[bar-iii-1];
+
+      //---- находим простое среднее приращений индикатора
+      Sum=0.0;
+      for(int iii=0; iii<int(std_period); iii++) Sum+=dFTMA[iii];
+      SMAdif=Sum/std_period;
+
+      //---- находим сумму квадратов разностей приращений и среднего
+      Sum=0.0;
+      for(int iii=0; iii<int(std_period); iii++) Sum+=MathPow(dFTMA[iii]-SMAdif,2);
+
+      //---- определяем итоговое значение среднеквадратичного отклонения StDev от приращения индикатора
+      StDev=MathSqrt(Sum/std_period);
+
+      //---- инициализация переменных
+      dstd=NormalizeDouble(dFTMA[0],_Digits+2);
+      Filter1=NormalizeDouble(dK1*StDev,_Digits+2);
+      Filter2=NormalizeDouble(dK2*StDev,_Digits+2);
+      BEARS1=EMPTY_VALUE;
+      BULLS1=EMPTY_VALUE;
+      BEARS2=EMPTY_VALUE;
+      BULLS2=EMPTY_VALUE;
+      ftma=LineBuffer[bar];
+
+      //---- вычисление индикаторных значений
+      if(dstd<-Filter1 && dstd>=-Filter2) BEARS1=ftma; //есть нисходящий тренд
+      if(dstd<-Filter2) BEARS2=ftma; //есть нисходящий тренд
+      if(dstd>+Filter1 && dstd<=+Filter2) BULLS1=ftma; //есть восходящий тренд
+      if(dstd>+Filter2) BULLS2=ftma; //есть восходящий тренд
+
+      //---- инициализация ячеек индикаторных буферов полученными значениями 
+      BullsBuffer1[bar]=BULLS1;
+      BearsBuffer1[bar]=BEARS1;
+      BullsBuffer2[bar]=BULLS2;
+      BearsBuffer2[bar]=BEARS2;
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+
+//| PriceSeries() function                                           |
+//+------------------------------------------------------------------+
+double PriceSeries
+(
+ uint applied_price,// Ценовая константа
+ uint   bar,// Индекс сдвига относительно текущего бара на указанное количество периодов назад или вперёд).
+ const double &Open[],
+ const double &Low[],
+ const double &High[],
+ const double &Close[]
+ )
+//PriceSeries(applied_price, bar, open, low, high, close)
+//+ - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -+
+  {
+//----
+   switch(applied_price)
+     {
+      //---- Ценовые константы из перечисления ENUM_APPLIED_PRICE
+      case  PRICE_CLOSE: return(Close[bar]);
+      case  PRICE_OPEN: return(Open [bar]);
+      case  PRICE_HIGH: return(High [bar]);
+      case  PRICE_LOW: return(Low[bar]);
+      case  PRICE_MEDIAN: return((High[bar]+Low[bar])/2.0);
+      case  PRICE_TYPICAL: return((Close[bar]+High[bar]+Low[bar])/3.0);
+      case  PRICE_WEIGHTED: return((2*Close[bar]+High[bar]+Low[bar])/4.0);
+
+      //----                            
+      case  8: return((Open[bar] + Close[bar])/2.0);
+      case  9: return((Open[bar] + Close[bar] + High[bar] + Low[bar])/4.0);
+      //----                                
+      case 10:
+        {
+         if(Close[bar]>Open[bar])return(High[bar]);
+         else
+           {
+            if(Close[bar]<Open[bar])
+               return(Low[bar]);
+            else return(Close[bar]);
+           }
+        }
+      //----         
+      case 11:
+        {
+         if(Close[bar]>Open[bar])return((High[bar]+Close[bar])/2.0);
+         else
+           {
+            if(Close[bar]<Open[bar])
+               return((Low[bar]+Close[bar])/2.0);
+            else return(Close[bar]);
+           }
+         break;
+        }
+      //----
+      default: return(Close[bar]);
+     }
+//----
+//return(0);
+  }
+//+------------------------------------------------------------------+