Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 2

2025-06-24 00:49:28 +01:00
commit 3dac0b5f2f
5047 changed files with 75091 additions and 0 deletions
@@ -0,0 +1,171 @@
+//+---------------------------------------------------------------------+
+//|                                               Directed_Movement.mq5 | 
+//|                                Copyright © 2015, Yuriy Tokman (YTG) |
+//|                                                  http://ytg.com.ua/ |
+//+---------------------------------------------------------------------+ 
+//| Для работы  индикатора  следует  положить файл SmoothAlgorithms.mqh |
+//| в папку (директорию): каталог_данных_терминала\\MQL5\Include        |
+//+---------------------------------------------------------------------+
+#property copyright "Copyright © 2015, Yuriy Tokman (YTG)"
+#property link      "http://ytg.com.ua/"
+//---- номер версии индикатора
+#property version   "1.00"
+//---- отрисовка индикатора в отдельном окне
+#property indicator_separate_window
+//---- количество индикаторных буферов 2
+#property indicator_buffers 2 
+//---- использовано всего одно графическое построение
+#property indicator_plots   1
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора              |
+//+----------------------------------------------+
+//---- отрисовка индикатора 1 в виде облака
+#property indicator_type1   DRAW_FILLING
+//---- в качестве цветов облака
+#property indicator_color1  clrForestGreen,clrOrangeRed
+//---- отображение метки индикатора
+#property indicator_label1  "Directed_Movement"
+//+----------------------------------------------+
+//|  Описание класса CXMA                        |
+//+----------------------------------------------+
+#include <SmoothAlgorithms.mqh> 
+//+----------------------------------------------+
+//---- объявление переменных класса CXMA из файла SmoothAlgorithms.mqh
+CXMA XMA1,XMA2;
+//+----------------------------------------------+
+//|  объявление перечислений                     |
+//+----------------------------------------------+
+/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
+  {
+   MODE_SMA_,  //SMA
+   MODE_EMA_,  //EMA
+   MODE_SMMA_, //SMMA
+   MODE_LWMA_, //LWMA
+   MODE_JJMA,  //JJMA
+   MODE_JurX,  //JurX
+   MODE_ParMA, //ParMA
+   MODE_T3,    //T3
+   MODE_VIDYA, //VIDYA
+   MODE_AMA,   //AMA
+  }; */
+//+----------------------------------------------+
+//|  объявление констант                         |
+//+----------------------------------------------+
+#define RESET  0 // Константа для возврата терминалу команды на пересчёт индикатора
+//+----------------------------------------------+
+//|  ВХОДНЫЕ ПАРАМЕТРЫ ИНДИКАТОРА                |
+//+----------------------------------------------+
+input uint                 RSIPeriod=14;         // период индикатора
+input ENUM_APPLIED_PRICE   RSIPrice=PRICE_CLOSE; // цена
+input Smooth_Method MA_Method1=MODE_SMA_;        // метод усреднения первого сглаживания 
+input int Length1=12;                            // глубина  первого сглаживания                    
+input int Phase1=15;                             // параметр первого сглаживания,
+//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
+input Smooth_Method MA_Method2=MODE_JJMA;        // метод усреднения второго сглаживания 
+input int Length2 = 5;                           // глубина  второго сглаживания 
+input int Phase2=15;                             // параметр второго сглаживания,
+//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
+//---- Для VIDIA это период CMO, для AMA это период медленной скользящей
+input int Shift=0;                               // сдвиг индикатора по горизонтали в барах
+//+----------------------------------------------+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double XRSIBuffer[];
+double XXRSIBuffer[];
+//---- Объявление целых переменных начала отсчёта данных
+int min_rates_total,min_rates_1,min_rates_2;
+//---- Объявление целых переменных для хендлов индикаторов
+int RSI_Handle;
+//+------------------------------------------------------------------+
+//| Custom indicator initialization function                         |
+//+------------------------------------------------------------------+  
+int OnInit()
+  {
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_1=int(RSIPeriod);
+   min_rates_2=min_rates_1+GetStartBars(MA_Method1,Length1,Phase1);
+   min_rates_total=min_rates_2+GetStartBars(MA_Method2,Length2,Phase2);
+
+//---- получение хендла индикатора iRSI
+   RSI_Handle=iRSI(NULL,0,RSIPeriod,RSIPrice);
+   if(RSI_Handle==INVALID_HANDLE)
+     {
+      Print(" Не удалось получить хендл индикатора iRSI");
+      return(INIT_FAILED);
+     }   
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,XRSIBuffer,INDICATOR_DATA);
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(1,XXRSIBuffer,INDICATOR_DATA);
+//---- осуществление сдвига индикатора 1 по горизонтали на Shift
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 1 на min_rates_total
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+
+//---- инициализации переменной для короткого имени индикатора
+   string shortname="Directed_Movement";
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,0);
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,0);
+//---- количество  горизонтальных уровней индикатора 3   
+   IndicatorSetInteger(INDICATOR_LEVELS,3);
+//---- значения горизонтальных уровней индикатора   
+   IndicatorSetDouble(INDICATOR_LEVELVALUE,0,70);
+   IndicatorSetDouble(INDICATOR_LEVELVALUE,1,50);
+   IndicatorSetDouble(INDICATOR_LEVELVALUE,2,30);
+//---- в качестве цветов линий горизонтальных уровней использованы цвета  
+   IndicatorSetInteger(INDICATOR_LEVELCOLOR,0,clrBlue);
+   IndicatorSetInteger(INDICATOR_LEVELCOLOR,1,clrGray);
+   IndicatorSetInteger(INDICATOR_LEVELCOLOR,2,clrMagenta);
+//---- в линии горизонтального уровня использован короткий штрих-пунктир  
+   IndicatorSetInteger(INDICATOR_LEVELSTYLE,0,STYLE_DASHDOTDOT);
+   IndicatorSetInteger(INDICATOR_LEVELSTYLE,1,STYLE_DASH);
+   IndicatorSetInteger(INDICATOR_LEVELSTYLE,2,STYLE_DASHDOTDOT);
+//---- завершение инициализации
+   return(INIT_SUCCEEDED);
+  }
+//+------------------------------------------------------------------+
+//| Custom indicator iteration function                              |
+//+------------------------------------------------------------------+
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double& high[],     // ценовой массив максимумов цены для расчёта индикатора
+                const double& low[],      // ценовой массив минимумов цены  для расчёта индикатора
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(BarsCalculated(RSI_Handle)<rates_total || rates_total<min_rates_total) return(RESET);
+
+//---- Объявление переменных с плавающей точкой  
+   double rsi[1];
+//---- Объявление целых переменных
+   int first,bar;
+
+//---- расчёт стартового номера first для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
+      first=min_rates_1; // стартовый номер для расчёта всех баров
+   else first=prev_calculated-1; // стартовый номер для расчёта новых баров
+
+//---- Основной цикл расчёта индикатора
+   for(bar=first; bar<rates_total && !IsStopped(); bar++)
+     {
+      //---- копируем вновь появившиеся данные в массив
+      if(CopyBuffer(RSI_Handle,0,rates_total-1-bar,1,rsi)<=0) return(RESET);
+      XRSIBuffer[bar]=XMA1.XMASeries(min_rates_1,prev_calculated,rates_total,MA_Method1,Phase1,Length1,rsi[0],bar,false);
+      XXRSIBuffer[bar]=XMA2.XMASeries(min_rates_2,prev_calculated,rates_total,MA_Method2,Phase2,Length2,XRSIBuffer[bar],bar,false);
+     }
+//----     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+
@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `Directed_Movement.mq5`
+
+### Screenshots:
+![Screenshot](picture__5.png)
+
+> Made with ❤️ for the trading community.