100 lines
7.8 KiB
Plaintext
100 lines
7.8 KiB
Plaintext
//+------------------------------------------------------------------+
|
|
//| CC.mq5 |
|
|
//| Copyright 2018, MetaQuotes Software Corp. |
|
|
//| https://mql5.com |
|
|
//+------------------------------------------------------------------+
|
|
#property copyright "Copyright 2018, MetaQuotes Software Corp."
|
|
#property link "https://mql5.com"
|
|
#property version "1.00"
|
|
#property description "John Ehlers' Cyclic Component oscillator"
|
|
#property indicator_separate_window
|
|
#property indicator_buffers 3
|
|
#property indicator_plots 1
|
|
//--- plot CC
|
|
#property indicator_label1 "CComponent"
|
|
#property indicator_type1 DRAW_LINE
|
|
#property indicator_color1 clrFireBrick
|
|
#property indicator_style1 STYLE_SOLID
|
|
#property indicator_width1 1
|
|
//--- input parameters
|
|
input uint InpPeriod = 20; // Period
|
|
input ENUM_APPLIED_PRICE InpAppliedPrice = PRICE_CLOSE; // Applied price
|
|
//--- indicator buffers
|
|
double BufferCC[];
|
|
double BufferHP[];
|
|
double BufferMA[];
|
|
//--- global variables
|
|
double alpha;
|
|
int period;
|
|
int handle_ma;
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator initialization function |
|
|
//+------------------------------------------------------------------+
|
|
int OnInit()
|
|
{
|
|
//--- set global variables
|
|
period=int(InpPeriod<3 ? 3 : InpPeriod);
|
|
alpha=(1.0-sin(2.0*M_PI/period))/cos(2.0*M_PI/period);
|
|
//--- indicator buffers mapping
|
|
SetIndexBuffer(0,BufferCC,INDICATOR_DATA);
|
|
SetIndexBuffer(1,BufferMA,INDICATOR_CALCULATIONS);
|
|
SetIndexBuffer(2,BufferHP,INDICATOR_CALCULATIONS);
|
|
//--- setting indicator parameters
|
|
IndicatorSetString(INDICATOR_SHORTNAME,"CCO("+(string)period+")");
|
|
IndicatorSetInteger(INDICATOR_DIGITS,Digits());
|
|
//--- setting buffer arrays as timeseries
|
|
ArraySetAsSeries(BufferCC,true);
|
|
ArraySetAsSeries(BufferHP,true);
|
|
ArraySetAsSeries(BufferMA,true);
|
|
//--- create MA's handle
|
|
ResetLastError();
|
|
handle_ma=iMA(NULL,PERIOD_CURRENT,1,0,MODE_SMA,InpAppliedPrice);
|
|
if(handle_ma==INVALID_HANDLE)
|
|
{
|
|
Print("The Fast iMA(1) object was not created: Error ",GetLastError());
|
|
return INIT_FAILED;
|
|
}
|
|
//---
|
|
return(INIT_SUCCEEDED);
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator iteration function |
|
|
//+------------------------------------------------------------------+
|
|
int OnCalculate(const int rates_total,
|
|
const int prev_calculated,
|
|
const datetime &time[],
|
|
const double &open[],
|
|
const double &high[],
|
|
const double &low[],
|
|
const double &close[],
|
|
const long &tick_volume[],
|
|
const long &volume[],
|
|
const int &spread[])
|
|
{
|
|
//--- Проверка на минимальное колиество баров для расчёта
|
|
if(rates_total<4) return 0;
|
|
//--- Проверка и расчёт количества просчитываемых баров
|
|
int limit=rates_total-prev_calculated;
|
|
if(limit>1)
|
|
{
|
|
limit=rates_total-4;
|
|
ArrayInitialize(BufferCC,EMPTY_VALUE);
|
|
ArrayInitialize(BufferHP,0);
|
|
ArrayInitialize(BufferMA,0);
|
|
}
|
|
//--- Подготовка данных
|
|
int copied=0,count=(limit==0 ? 1 : rates_total);
|
|
copied=CopyBuffer(handle_ma,0,0,count,BufferMA);
|
|
if(copied!=count) return 0;
|
|
//--- Расчёт индикатора
|
|
for(int i=limit; i>=0 && !IsStopped(); i--)
|
|
{
|
|
BufferHP[i]=0.5*(1.0+alpha)*(BufferMA[i]-BufferMA[i+1])+alpha*BufferHP[i+1];
|
|
BufferCC[i]=(BufferHP[i]+2.*BufferHP[i+1]+2.*BufferHP[i+2]+BufferHP[i+3])/6.;
|
|
}
|
|
|
|
//--- return value of prev_calculated for next call
|
|
return(rates_total);
|
|
}
|
|
//+------------------------------------------------------------------+
|