115 lines
8.9 KiB
Plaintext
115 lines
8.9 KiB
Plaintext
//+------------------------------------------------------------------+
|
|
//| CA.mq5 |
|
|
//| Copyright 2018, MetaQuotes Software Corp. |
|
|
//| https://mql5.com |
|
|
//+------------------------------------------------------------------+
|
|
#property copyright "Copyright 2018, MetaQuotes Software Corp."
|
|
#property link "https://mql5.com"
|
|
#property version "1.00"
|
|
#property description "Corrected Average indicator"
|
|
#property indicator_chart_window
|
|
#property indicator_buffers 3
|
|
#property indicator_plots 1
|
|
//--- plot CA
|
|
#property indicator_label1 "CA"
|
|
#property indicator_type1 DRAW_LINE
|
|
#property indicator_color1 clrSienna
|
|
#property indicator_style1 STYLE_SOLID
|
|
#property indicator_width1 1
|
|
//--- input parameters
|
|
input uint InpPeriod = 14; // Period
|
|
input ENUM_MA_METHOD InpMethod = MODE_SMA; // Method
|
|
input ENUM_APPLIED_PRICE InpAppliedPrice = PRICE_CLOSE; // Applied price
|
|
//--- indicator buffers
|
|
double BufferCA[];
|
|
double BufferMA[];
|
|
double BufferDev[];
|
|
//--- global variables
|
|
int period;
|
|
int handle_ma;
|
|
int handle_dev;
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator initialization function |
|
|
//+------------------------------------------------------------------+
|
|
int OnInit()
|
|
{
|
|
//--- set global variables
|
|
period=int(InpPeriod<1 ? 1 : InpPeriod);
|
|
//--- indicator buffers mapping
|
|
SetIndexBuffer(0,BufferCA,INDICATOR_DATA);
|
|
SetIndexBuffer(1,BufferMA,INDICATOR_CALCULATIONS);
|
|
SetIndexBuffer(2,BufferDev,INDICATOR_CALCULATIONS);
|
|
//--- setting indicator parameters
|
|
IndicatorSetString(INDICATOR_SHORTNAME,"CA ("+(string)period+")");
|
|
IndicatorSetInteger(INDICATOR_DIGITS,Digits());
|
|
//--- setting plot buffer parameters
|
|
PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,period);
|
|
//--- setting buffer arrays as timeseries
|
|
ArraySetAsSeries(BufferCA,true);
|
|
ArraySetAsSeries(BufferMA,true);
|
|
ArraySetAsSeries(BufferDev,true);
|
|
//--- create MA's handles
|
|
ResetLastError();
|
|
handle_ma=iMA(NULL,PERIOD_CURRENT,period,0,InpMethod,InpAppliedPrice);
|
|
if(handle_ma==INVALID_HANDLE)
|
|
{
|
|
Print("The iMA(",(string)period,") object was not created: Error ",GetLastError());
|
|
return INIT_FAILED;
|
|
}
|
|
handle_dev=iStdDev(NULL,PERIOD_CURRENT,period,0,MODE_SMA,InpAppliedPrice);
|
|
if(handle_dev==INVALID_HANDLE)
|
|
{
|
|
Print("The iStdDev(",(string)period,") object was not created: Error ",GetLastError());
|
|
return INIT_FAILED;
|
|
}
|
|
//---
|
|
return(INIT_SUCCEEDED);
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator iteration function |
|
|
//+------------------------------------------------------------------+
|
|
int OnCalculate(const int rates_total,
|
|
const int prev_calculated,
|
|
const datetime &time[],
|
|
const double &open[],
|
|
const double &high[],
|
|
const double &low[],
|
|
const double &close[],
|
|
const long &tick_volume[],
|
|
const long &volume[],
|
|
const int &spread[])
|
|
{
|
|
//--- Проверка и расчёт количества просчитываемых баров
|
|
if(rates_total<4) return 0;
|
|
//--- Проверка и расчёт количества просчитываемых баров
|
|
int limit=rates_total-prev_calculated;
|
|
if(limit>1)
|
|
{
|
|
limit=rates_total-2;
|
|
ArrayInitialize(BufferCA,EMPTY_VALUE);
|
|
ArrayInitialize(BufferMA,0);
|
|
ArrayInitialize(BufferDev,0);
|
|
BufferCA[limit]=0;
|
|
}
|
|
//--- Подготовка данных
|
|
int count=(limit>1 ? rates_total : 1),copied=0;
|
|
copied=CopyBuffer(handle_ma,0,0,count,BufferMA);
|
|
if(copied!=count) return 0;
|
|
copied=CopyBuffer(handle_dev,0,0,count,BufferDev);
|
|
if(copied!=count) return 0;
|
|
|
|
//--- Расчёт индикатора
|
|
for(int i=limit; i>=0 && !IsStopped(); i--)
|
|
{
|
|
double dev=BufferDev[i]*BufferDev[i];
|
|
double diff=(BufferCA[i+1]-BufferMA[i])*(BufferCA[i+1]-BufferMA[i]);
|
|
double k=(diff>dev && diff!=0 ? 1.0-dev/diff : 0);
|
|
|
|
BufferCA[i]=BufferCA[i+1]+k*(BufferMA[i]-BufferCA[i+1]);
|
|
}
|
|
|
|
//--- return value of prev_calculated for next call
|
|
return(rates_total);
|
|
}
|
|
//+------------------------------------------------------------------+
|