160 lines
7.5 KiB
Plaintext
160 lines
7.5 KiB
Plaintext
//+---------------------------------------------------------------------+
|
|
//| BaseVolatility.mq5 |
|
|
//| Copyright © 2015, fxborg |
|
|
//| http://fxborg-labo.hateblo.jp/ |
|
|
//+---------------------------------------------------------------------+
|
|
//| Для работы индикатора следует положить файл SmoothAlgorithms.mqh |
|
|
//| в папку (директорию): каталог_данных_терминала\\MQL5\Include |
|
|
//+---------------------------------------------------------------------+
|
|
#property copyright "Copyright © 2015, fxborg"
|
|
#property link "http://fxborg-labo.hateblo.jp/"
|
|
#property description "Сглаженный индикатор стандартного отклонения"
|
|
//---- номер версии индикатора
|
|
#property version "1.00"
|
|
//---- отрисовка индикатора в отдельном окне
|
|
#property indicator_separate_window
|
|
//---- количество индикаторных буферов 1
|
|
#property indicator_buffers 1
|
|
//---- использовано всего одно графическое построение
|
|
#property indicator_plots 1
|
|
//+-----------------------------------+
|
|
//| Параметры отрисовки индикатора |
|
|
//+-----------------------------------+
|
|
//---- отрисовка индикатора в виде линии
|
|
#property indicator_type1 DRAW_LINE
|
|
//---- в качестве цвета линии индикатора использован сине-фиолетовый цвет
|
|
#property indicator_color1 clrBlueViolet
|
|
//---- линия индикатора - сплошная линия
|
|
#property indicator_style1 STYLE_SOLID
|
|
//---- толщина линии индикатора равна 2
|
|
#property indicator_width1 2
|
|
//---- отображение метки индикатора
|
|
#property indicator_label1 "BaseVolatility"
|
|
//+-----------------------------------+
|
|
//| Описание классов усреднений |
|
|
//+-----------------------------------+
|
|
#include <SmoothAlgorithms.mqh>
|
|
//+-----------------------------------+
|
|
//---- объявление переменных классов CXMA и CStdDeviation из файла SmoothAlgorithms.mqh
|
|
CXMA XMA1,XMA2;
|
|
CStdDeviation STD;
|
|
//+-----------------------------------+
|
|
//| Объявление перечислений |
|
|
//+-----------------------------------+
|
|
enum Applied_price_ //тип константы
|
|
{
|
|
PRICE_CLOSE_ = 1, //Close
|
|
PRICE_OPEN_, //Open
|
|
PRICE_HIGH_, //High
|
|
PRICE_LOW_, //Low
|
|
PRICE_MEDIAN_, //Median Price (HL/2)
|
|
PRICE_TYPICAL_, //Typical Price (HLC/3)
|
|
PRICE_WEIGHTED_, //Weighted Close (HLCC/4)
|
|
PRICE_SIMPL_, //Simpl Price (OC/2)
|
|
PRICE_QUARTER_, //Quarted Price (HLOC/4)
|
|
PRICE_TRENDFOLLOW0_, //TrendFollow_1 Price
|
|
PRICE_TRENDFOLLOW1_, //TrendFollow_2 Price
|
|
PRICE_DEMARK_ //Demark Price
|
|
};
|
|
//+-----------------------------------+
|
|
//| Объявление перечислений |
|
|
//+-----------------------------------+
|
|
/*enum Smooth_Method - перечисление объявлено в файле SmoothAlgorithms.mqh
|
|
{
|
|
MODE_SMA_, //SMA
|
|
MODE_EMA_, //EMA
|
|
MODE_SMMA_, //SMMA
|
|
MODE_LWMA_, //LWMA
|
|
MODE_JJMA, //JJMA
|
|
MODE_JurX, //JurX
|
|
MODE_ParMA, //ParMA
|
|
MODE_T3, //T3
|
|
MODE_VIDYA, //VIDYA
|
|
MODE_AMA, //AMA
|
|
}; */
|
|
//+-----------------------------------+
|
|
//| Входные параметры индикатора |
|
|
//+-----------------------------------+
|
|
input Smooth_Method MA_Method1=MODE_SMA; // Метод усреднения скользящей средней
|
|
input int Length1=10; // Глубина усреднения скользящей средней
|
|
input int Phase1=15; // Параметр усреднения скользящей средней
|
|
//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
|
|
//---- для VIDIA это период CMO, для AMA это период медленной скользящей
|
|
input Smooth_Method MA_Method2=MODE_JJMA; // Метод сглаживания стандартного отклонения
|
|
input int Length2=9; // Глубина сглаживания стандартного отклонения
|
|
input int Phase2=100; // Параметр сглаживания стандартного отклонения
|
|
//---- для JJMA изменяющийся в пределах -100 ... +100, влияет на качество переходного процесса;
|
|
//---- для VIDIA это период CMO, для AMA это период медленной скользящей
|
|
input Applied_price_ IPC=PRICE_CLOSE; // Ценовая константа
|
|
input int Shift=0; // Сдвиг индикатора по горизонтали в барах
|
|
//+-----------------------------------+
|
|
//---- объявление динамического массива, который будет в
|
|
//---- дальнейшем использован в качестве индикаторного буфера
|
|
double ExtLineBuffer[];
|
|
//---- объявление целочисленных переменных начала отсчёта данных
|
|
int min_rates_total,min_rates_1,min_rates_2;
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator initialization function |
|
|
//+------------------------------------------------------------------+
|
|
void OnInit()
|
|
{
|
|
//---- инициализация переменных начала отсчёта данных
|
|
min_rates_1=GetStartBars(MA_Method1,Length1,Phase1)+1;
|
|
min_rates_2=min_rates_1+int(Length1);
|
|
min_rates_total=min_rates_2+GetStartBars(MA_Method2,Length2,Phase2);
|
|
//---- превращение динамического массива в индикаторный буфер
|
|
SetIndexBuffer(0,ExtLineBuffer,INDICATOR_DATA);
|
|
//---- осуществление сдвига индикатора 1 по горизонтали
|
|
PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
|
|
//---- осуществление сдвига начала отсчёта отрисовки индикатора
|
|
PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
|
|
//---- установка значений индикатора, которые не будут видимы на графике
|
|
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
|
|
//---- инициализация переменной для короткого имени индикатора
|
|
string shortname;
|
|
StringConcatenate(shortname,"BaseVolatility(",Length1,", ",Length2,")");
|
|
//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
|
|
IndicatorSetString(INDICATOR_SHORTNAME,shortname);
|
|
//--- определение точности отображения значений индикатора
|
|
IndicatorSetInteger(INDICATOR_DIGITS,4);
|
|
//---- завершение инициализации
|
|
}
|
|
//+------------------------------------------------------------------+
|
|
//| Custom indicator iteration function |
|
|
//+------------------------------------------------------------------+
|
|
int OnCalculate(const int rates_total, // количество истории в барах на текущем тике
|
|
const int prev_calculated,// количество истории в барах на предыдущем тике
|
|
const datetime &time[],
|
|
const double &open[],
|
|
const double &high[],
|
|
const double &low[],
|
|
const double &close[],
|
|
const long &tick_volume[],
|
|
const long &volume[],
|
|
const int &spread[])
|
|
{
|
|
//---- проверка количества баров на достаточность для расчёта
|
|
if(rates_total<min_rates_total) return(0);
|
|
//---- объявление переменных с плавающей точкой
|
|
double price,xma,stdev,xstdev;
|
|
//---- объявление целочисленных переменных и получение уже посчитанных баров
|
|
int first,bar;
|
|
//---- расчёт стартового номера first для цикла пересчёта баров
|
|
if(prev_calculated>rates_total || prev_calculated<=0) // проверка на первый старт расчёта индикатора
|
|
first=0; // стартовый номер для расчёта всех баров
|
|
else first=prev_calculated-1; // стартовый номер для расчёта новых баров
|
|
//---- основной цикл расчёта индикатора
|
|
for(bar=first; bar<rates_total && !IsStopped(); bar++)
|
|
{
|
|
//---- вызов функции PriceSeries для получения входной цены price_
|
|
price=PriceSeries(IPC,bar,open,low,high,close);
|
|
xma=XMA1.XMASeries(0,prev_calculated,rates_total,MA_Method1,Phase1,Length1,price,bar,false);
|
|
stdev=STD.StdDevSeries(min_rates_1,prev_calculated,rates_total,Length1,1.0,price,xma,bar,false);
|
|
xstdev=XMA2.XMASeries(min_rates_2,prev_calculated,rates_total,MA_Method2,Phase2,Length2,stdev,bar,false);
|
|
ExtLineBuffer[bar]=xstdev;
|
|
}
|
|
//----
|
|
return(rates_total);
|
|
}
|
|
//+------------------------------------------------------------------+
|