Initial commit: MQL5 Indicators Collection (MetaTrader 5) - Part 1

2025-06-24 00:44:28 +01:00
commit d847865d8a
5024 changed files with 75931 additions and 0 deletions
@@ -0,0 +1,21 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+
+## Files included:
+### Source Files:
+- `darvasboxes_system_digit.mq5`
+
+### Screenshots:
+![Screenshot](picture__24.png)
+
+> Made with ❤️ for the trading community.
@@ -0,0 +1,330 @@
+//+------------------------------------------------------------------+
+//|                                     DarvasBoxes_System_Digit.mq5 |
+//|                               Copyright © 2013, Nikolay Kositsin | 
+//|                              Khabarovsk,   farria@mail.redcom.ru | 
+//+------------------------------------------------------------------+ 
+#property copyright "Copyright © 2013, Nikolay Kositsin"
+#property link "farria@mail.redcom.ru"
+#property description "Пробойная система с использованием индикатора DarvasBoxes"
+//---- номер версии индикатора
+#property version   "1.00"
+//---- отрисовка индикатора в главном окне
+#property indicator_chart_window
+//---- для расчёта и отрисовки индикатора использовано семь буферов
+#property indicator_buffers 7
+//---- использовано четыре графических построения
+#property indicator_plots   4
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора 1            |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде одноцветного облака
+#property indicator_type1   DRAW_FILLING
+//---- в качестве цвета индикатора использован WhiteSmoke цвет
+#property indicator_color1  clrWhiteSmoke
+//---- отображение метки индикатора
+#property indicator_label1  "DarvasBoxes"
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора 2            |
+//+----------------------------------------------+
+//---- отрисовка индикатора 2 в виде линии
+#property indicator_type2   DRAW_LINE
+//---- в качестве цвета бычей линии индикатора использован MediumSeaGreen цвет
+#property indicator_color2  clrMediumSeaGreen
+//---- линия индикатора 2 - непрерывная кривая
+#property indicator_style2  STYLE_SOLID
+//---- толщина линии индикатора 2 равна 2
+#property indicator_width2  2
+//---- отображение бычей метки индикатора
+#property indicator_label2  "Upper DarvasBoxes"
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора 3            |
+//+----------------------------------------------+
+//---- отрисовка индикатора 3 в виде линии
+#property indicator_type3   DRAW_LINE
+//---- в качестве цвета медвежьей линии индикатора использован Magenta цвет
+#property indicator_color3  clrMagenta
+//---- линия индикатора 3 - непрерывная кривая
+#property indicator_style3  STYLE_SOLID
+//---- толщина линии индикатора 3 равна 2
+#property indicator_width3  2
+//---- отображение медвежьей метки индикатора
+#property indicator_label3  "Lower DarvasBoxes"
+//+----------------------------------------------+
+//|  Параметры отрисовки индикатора 4            |
+//+----------------------------------------------+
+//---- отрисовка индикатора в виде четырёхцветной гистограммы
+#property indicator_type4 DRAW_COLOR_HISTOGRAM2
+//---- в качестве цветов четырёхцветной гистограммы использованы
+#property indicator_color4 clrDeepPink,clrPurple,clrGray,clrMediumBlue,clrDodgerBlue
+//---- линия индикатора - сплошная
+#property indicator_style4 STYLE_SOLID
+//---- толщина линии индикатора равна 2
+#property indicator_width4 2
+//---- отображение метки индикатора
+#property indicator_label4 "DarvasBoxes_BARS"
+
+//+----------------------------------------------+
+//| Входные параметры индикатора                 |
+//+----------------------------------------------+
+input string  SirName="DarvasBoxes_Digit_Grid";     //Первая часть имени графических объектов
+input bool symmetry=true;
+input uint Digit=2;                                 //количество разрядов округления
+input bool RoundPrice=true;                         //округлять цены
+input bool ShowPrice=true;                          //показывать ценовые метки
+input uint   Shift=2;                               //сдвиг канала по горизонтали в барах 
+input color Upper_color=clrBlue;
+input color Lower_color=clrMagenta;
+input uint Fontsizex= 2;                            //размер ценовых меток
+//+----------------------------------------------+
+//---- объявление динамических массивов, которые будут в 
+// дальнейшем использованы в качестве индикаторных буферов
+double Up1Buffer[],Dn1Buffer[];
+double Up2Buffer[],Dn2Buffer[];
+double UpIndBuffer[],DnIndBuffer[],ColorIndBuffer[];
+//---- Объявление целых переменных начала отсчёта данных
+int min_rates_total;
+//---- Объявление стрингов для текстовых меток
+string upper_name,lower_name;
+double PointPow10;
+//+------------------------------------------------------------------+
+//| Custom indicator initialization function                         |
+//+------------------------------------------------------------------+  
+void OnInit()
+  {
+//---- Инициализация переменных начала отсчёта данных
+   min_rates_total=int(2+Shift);
+//---- Инициализация стрингов
+   upper_name=SirName+" upper text lable";
+   lower_name=SirName+" lower text lable";
+//---- инициализация переменных         
+   PointPow10=_Point*MathPow(10,Digit);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(0,Up1Buffer,INDICATOR_DATA);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(Up1Buffer,true);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(1,Dn1Buffer,INDICATOR_DATA);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(Dn1Buffer,true);
+   
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(2,Up2Buffer,INDICATOR_DATA);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(Up2Buffer,true);
+
+//---- превращение динамического массива в индикаторный буфер
+   SetIndexBuffer(3,Dn2Buffer,INDICATOR_DATA);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(Dn2Buffer,true);
+   
+//---- превращение динамического массива IndBuffer в индикаторный буфер
+   SetIndexBuffer(4,UpIndBuffer,INDICATOR_DATA);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(UpIndBuffer,true);
+
+//---- превращение динамического массива IndBuffer в индикаторный буфер
+   SetIndexBuffer(5,DnIndBuffer,INDICATOR_DATA);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(DnIndBuffer,true);
+
+//---- превращение динамического массива в цветовой, индексный буфер   
+   SetIndexBuffer(6,ColorIndBuffer,INDICATOR_COLOR_INDEX);
+//---- индексация элементов в буфере как в таймсерии
+   ArraySetAsSeries(ColorIndBuffer,true);
+   
+//---- осуществление сдвига индикатора 1 по горизонтали на Shift
+   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 1 на min_rates_total
+   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
+   
+//---- осуществление сдвига индикатора 2 по горизонтали на Shift
+   PlotIndexSetInteger(1,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 2 на min_rates_total
+   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
+   
+//---- осуществление сдвига индикатора 3 по горизонтали на Shift
+   PlotIndexSetInteger(2,PLOT_SHIFT,Shift);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 3 на min_rates_total
+   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,min_rates_total);
+   
+//---- осуществление сдвига индикатора 3 по горизонтали на Shift
+   PlotIndexSetInteger(3,PLOT_SHIFT,0);
+//---- осуществление сдвига начала отсчёта отрисовки индикатора 4 на min_rates_total
+   PlotIndexSetInteger(3,PLOT_DRAW_BEGIN,min_rates_total);
+//---- установка значений индикатора, которые не будут видимы на графике
+   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,0);
+
+//---- инициализации переменной для короткого имени индикатора
+   string shortname;
+   StringConcatenate(shortname,"DarvasBoxes(",Shift,")");
+//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
+   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
+//--- определение точности отображения значений индикатора
+   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
+//----
+  }
+//+------------------------------------------------------------------+
+//| Custom indicator deinitialization function                       |
+//+------------------------------------------------------------------+    
+void OnDeinit(const int reason)
+  {
+//----
+   ObjectDelete(0,upper_name);
+   ObjectDelete(0,lower_name);
+//----
+   ChartRedraw(0);
+  }
+//+------------------------------------------------------------------+
+//| Custom indicator iteration function                              |
+//+------------------------------------------------------------------+
+int OnCalculate(
+                const int rates_total,    // количество истории в барах на текущем тике
+                const int prev_calculated,// количество истории в барах на предыдущем тике
+                const datetime &time[],
+                const double &open[],
+                const double &high[],
+                const double &low[],
+                const double &close[],
+                const long &tick_volume[],
+                const long &volume[],
+                const int &spread[]
+                )
+  {
+//---- проверка количества баров на достаточность для расчёта
+   if(rates_total<min_rates_total) return(0);
+
+//---- индексация элементов в массивах как в таймсериях  
+   ArraySetAsSeries(open,true);
+   ArraySetAsSeries(close,true);
+   ArraySetAsSeries(high,true);
+   ArraySetAsSeries(low,true);
+   ArraySetAsSeries(time,true);
+
+//---- Объявление целых переменных
+   int limit;
+//---- Объявление статических переменных
+   static int state,STATE;
+   static double box_top,box_bottom,BOX_TOP,BOX_BUTTOM;
+
+//---- расчёты стартового номера limit для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0)// проверка на первый старт расчёта индикатора
+     {
+      limit=rates_total-min_rates_total; // стартовый номер для расчёта всех баров
+      BOX_TOP=high[limit+1];
+      BOX_BUTTOM=low[limit+1];
+      STATE=1;
+     }
+   else
+     {
+      limit=rates_total-prev_calculated; // стартовый номер для расчёта новых баров
+     }
+
+//---- восстанавливаем значения переменных
+   state=STATE;
+   box_top=BOX_TOP;
+   box_bottom=BOX_BUTTOM;
+
+//---- основной цикл расчёта индикатора
+   for(int bar=limit; bar>=0 && !IsStopped(); bar--)
+     {
+      switch(state)
+        {
+         case 1:  box_top=high[bar]; if(symmetry)box_bottom=low[bar]; break;
+         case 2:  if(box_top<=high[bar]) box_top=high[bar]; break;
+         case 3:  if(box_top> high[bar]) box_bottom=low[bar]; else box_top=high[bar]; break;
+         case 4:  if(box_top > high[bar]) {if(box_bottom >= low[bar]) box_bottom=low[bar];} else box_top=high[bar]; break;
+         case 5:  if(box_top > high[bar]) {if(box_bottom >= low[bar]) box_bottom=low[bar];} else box_top=high[bar]; state=0; break;
+        }
+
+      Up1Buffer[bar]=box_top;
+      Dn1Buffer[bar]=box_bottom;     
+      Up1Buffer[bar]=Up2Buffer[bar]=PointPow10*MathCeil(Up1Buffer[bar]/PointPow10);
+      Dn1Buffer[bar]=Dn2Buffer[bar]=PointPow10*MathFloor(Dn1Buffer[bar]/PointPow10);
+      state++;
+      
+      //---- запоминаем значения переменных перед прогонами на текущем баре
+      if(bar==1)
+        {
+         STATE=state;
+         BOX_TOP=box_top;
+         BOX_BUTTOM=box_bottom;
+        }
+     }
+
+//---- расчёт стартового номера limit для цикла пересчёта баров
+   if(prev_calculated>rates_total || prev_calculated<=0) limit-=int(Shift);     
+//---- Основной цикл раскраски баров индикатора
+   for(int bar=limit; bar>=0 && !IsStopped(); bar--)
+     {
+      int clr=2;
+      UpIndBuffer[bar]=0.0;
+      DnIndBuffer[bar]=0.0;
+      
+      if(close[bar]>Up1Buffer[bar+Shift])
+        {
+         if(open[bar]<close[bar]) clr=4;
+         else clr=3;
+         UpIndBuffer[bar]=high[bar];
+         DnIndBuffer[bar]=low[bar];
+        }
+
+      if(close[bar]<Dn1Buffer[bar+Shift])
+        {
+         if(open[bar]>close[bar]) clr=0;
+         else clr=1;
+         UpIndBuffer[bar]=high[bar];
+         DnIndBuffer[bar]=low[bar];
+        }
+
+      ColorIndBuffer[bar]=clr;
+     }
+   if(ShowPrice)
+     {
+      int bar0=int(Shift);
+      datetime time0=time[0];
+      SetRightPrice(0,upper_name,0,time0,Up1Buffer[bar0],Upper_color);
+      SetRightPrice(0,lower_name,0,time0,Dn1Buffer[bar0],Lower_color);
+     }
+//----
+   ChartRedraw(0);     
+   return(rates_total);
+  }
+//+------------------------------------------------------------------+
+//|  RightPrice creation                                             |
+//+------------------------------------------------------------------+
+void CreateRightPrice(long chart_id,// chart ID
+                      string   name,              // object name
+                      int      nwin,              // window index
+                      datetime time,              // price level time
+                      double   price,             // price level
+                      color    Color              // Text color
+                      )
+//---- 
+  {
+//----
+   ObjectCreate(chart_id,name,OBJ_ARROW_RIGHT_PRICE,nwin,time,price);
+   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
+   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);
+   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,2);
+//----
+  }
+//+------------------------------------------------------------------+
+//|  RightPrice reinstallation                                       |
+//+------------------------------------------------------------------+
+void SetRightPrice(long chart_id,// chart ID
+                   string   name,              // object name
+                   int      nwin,              // window index
+                   datetime time,              // price level time
+                   double   price,             // price level
+                   color    Color              // Text color
+                   )
+//---- 
+  {
+//----
+   if(ObjectFind(chart_id,name)==-1) CreateRightPrice(chart_id,name,nwin,time,price,Color);
+   else ObjectMove(chart_id,name,0,time,price);
+//----
+  }
+//+------------------------------------------------------------------+