//+------------------------------------------------------------------+
//|                                           Market_Scanner_Pro.mq5 |
//|                    QuantScan 5.1 - Multi-TF Global Sentiment     |
//|                    Copyright 2026, xxxxxxxx                      |
//+------------------------------------------------------------------+
#property copyright "Copyright 2026, xxxxxxxx"
#property version   "5.10" // Global Sentiment on H1, M15, M5
#property description "Exports 'QuantScan 5.0' for LLM Analysis."
#property description "3-Layer Logic & Multi-TF Risk Sentiment."
#property script_show_inputs

//--- Include Custom Calculators
#include <MyIncludes\DSMA_Calculator.mqh>
#include <MyIncludes\VWAP_Calculator.mqh>
#include <MyIncludes\Laguerre_RSI_Calculator.mqh>
#include <MyIncludes\TSI_Calculator.mqh>
#include <MyIncludes\MurreyMath_Calculator.mqh>
#include <MyIncludes\ATR_Calculator.mqh>
#include <MyIncludes\Bollinger_Bands_Calculator.mqh>
#include <MyIncludes\KeltnerChannel_Calculator.mqh>
#include <MyIncludes\MathStatistics_Calculator.mqh>
#include <MyIncludes\ZScore_Calculator.mqh>
#include <MyIncludes\EfficiencyRatio_Calculator.mqh>
#include <MyIncludes\RelativeVolume_Calculator.mqh>

//--- Input Parameters ---
input group "Scanner Config"
input bool     InpUseMarketWatch = false;
input string   InpSymbolList     = "EURUSD,USDJPY,GBPUSD,USDCHF,AUDUSD,XAUUSD,US500,DE40,XTIUSD,ETHUSD";
input string   InpBenchmark      = "US500";
input string   InpForexBench     = "DX";
input string   InpBrokerTimeZone = "EET (UTC+2)";
input int      InpScanHistory    = 500;

input group "Benchmark Settings"
input int      InpBetaLookback   = 60;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
input group "Timeframes (3-Layer Model)"
input ENUM_TIMEFRAMES InpTFSlow    = PERIOD_H1;  // Layer 1: Context/Sentiment Base
input ENUM_TIMEFRAMES InpTFMiddle  = PERIOD_M15; // Layer 2: Flow/Session Sentiment
input ENUM_TIMEFRAMES InpTFFast    = PERIOD_M5;  // Layer 3: Trigger/Shock Sentiment

input group "Metric Settings"
input int      InpDSMAPeriod     = 40;
input double   InpLaguerreGamma  = 0.50;
input int      InpMurreyPeriod   = 64;
input int      InpATRPeriod      = 14;
input int      InpRSBars         = 24;
input int      InpRVOLPeriod     = 20;
input int      InpERPeriod       = 10;
input int      InpZScorePeriod   = 20;

input group "TSI Settings"
input int      InpTSI_Slow       = 25;
input int      InpTSI_Fast       = 13;
input int      InpTSI_Signal     = 13;

input group "Squeeze Settings"
input int      InpSqueezeLength  = 20;
input double   InpBBMult         = 2.0;
input double   InpKCMult         = 1.5;

//--- Struct for QuantScan Data
struct QuantData
  {
   string            timestamp;
   string            symbol;
   double            price;

   // --- Layer 1: H1 Context ---
   double            trend_score;
   double            trend_qual;
   string            zone;
   string            rel_strength_str;
   string            beta_str;
   string            alpha_str;

   // --- Layer 2: M15 Flow ---
   double            m15_momentum;
   double            m15_vol_qual;
   string            m15_squeeze;
   double            m15_z_score;
   double            m15_vola_regime;
   string            m15_tsi_dir;

   // --- Layer 3: M5 Trigger ---
   double            m5_momentum;
   double            m5_vol_qual;
   string            m5_tsi_dir;
   double            m5_velocity;

   // --- Composites ---
   double            rev_prob;
   string            absorption;
  };

//+------------------------------------------------------------------+
//| Helper: Detect Asset Class                                       |
//+------------------------------------------------------------------+
bool IsForexPair(string sym)
  {
   if(sym == InpBenchmark || sym == InpForexBench)
      return false;
   if(StringFind(sym, "USD") != -1 || StringFind(sym, "EUR") != -1 ||
      StringFind(sym, "JPY") != -1 || StringFind(sym, "CHF") != -1 ||
      StringFind(sym, "AUD") != -1 || StringFind(sym, "CAD") != -1 || StringFind(sym, "NZD") != -1)
     {
      if(StringFind(sym, "XAU")!=-1 || StringFind(sym, "XTI")!=-1 || StringFind(sym, "WTI")!=-1 || StringFind(sym, "BTC")!=-1 || StringFind(sym, "ETH")!=-1)
         return false;
      return true;
     }
   return false;
  }

//+------------------------------------------------------------------+
//| Helper: Get Sentiment String for TF                              |
//+------------------------------------------------------------------+
string GetSentimentForTF(ENUM_TIMEFRAMES tf)
  {
// Uses Last Closed Bar change vs Prev
   double u_close[2], d_close[2];

// Fetch 2 bars. Index 0=Oldest (Prev), Index 1=Newest (Last Closed)
// Note: If using FetchData logic (ArraySetAsSeries false), copy from end.
// But CopyClose(..., 0, 2) returns: [0]=Bar 1 ago, [1]=Bar 0 (Current) ?
// Docs: CopyClose(..., start_pos, count, buffer) -> start_pos relative to current.
// start_pos=0 is current bar. start_pos=1 is closed bar.
// Let's create array of 2 elements from start_pos=1 (last closed two candles).
// So [0] = Bar 2, [1] = Bar 1.

   if(CopyClose(InpBenchmark, tf, 1, 2, u_close) != 2)
      return "N/A";
   if(CopyClose(InpForexBench, tf, 1, 2, d_close) != 2)
      return "N/A";

   double us500_chg = (u_close[1] - u_close[0]);
   double dxy_chg   = (d_close[1] - d_close[0]);

   double us500_pct = (u_close[0]!=0) ? (us500_chg / u_close[0])*100 : 0;
   double dxy_pct   = (d_close[0]!=0) ? (dxy_chg / d_close[0])*100 : 0;

   string state = "MIXED";
   if(dxy_chg < 0 && us500_chg > 0)
      state = "RISK-ON";
   else
      if(dxy_chg > 0 && us500_chg < 0)
         state = "RISK-OFF";
      else
         if(dxy_chg > 0 && us500_chg > 0)
            state = "STRESS";
         else
            if(dxy_chg < 0 && us500_chg < 0)
               state = "DEFLATION";

// Format: "RISK-ON (S: +0.2% D: -0.1%)"
   string tf_name = EnumToString(tf);
   StringReplace(tf_name, "PERIOD_", "");
   return StringFormat("%s: %s (US:%.2f%% DX:%.2f%%)", tf_name, state, us500_pct, dxy_pct);
  }

//+------------------------------------------------------------------+
//| Script Start                                                     |
//+------------------------------------------------------------------+
void OnStart()
  {
   string symbols[];
   int total_symbols = 0;

   if(InpUseMarketWatch)
     {
      total_symbols = SymbolsTotal(true);
      ArrayResize(symbols, total_symbols);
      for(int i=0; i<total_symbols; i++)
         symbols[i] = SymbolName(i, true);
     }
   else
     {
      string sep = ",";
      ushort u_sep = StringGetCharacter(sep, 0);
      total_symbols = StringSplit(InpSymbolList, u_sep, symbols);
     }

// --- Global Sentiment Analysis (Multi-TF) ---
   string sentiment_line = "### GLOBAL_SENTIMENT | ";

   bool has_us500 = SymbolSelect(InpBenchmark, true);
   bool has_dxy   = SymbolSelect(InpForexBench, true);

   if(has_us500 && has_dxy)
     {
      string s1 = GetSentimentForTF(InpTFSlow);
      string s2 = GetSentimentForTF(InpTFMiddle);
      string s3 = GetSentimentForTF(InpTFFast);

      sentiment_line += s1 + " | " + s2 + " | " + s3 + " ###";
     }
   else
     {
      sentiment_line += "Benchmarks Missing (Check High/Low settings) ###";
     }

// --- Benchmark for RS (H1 Context) ---
   double bench_change_pct = 0.0;
   if(has_us500)
     {
      double b_close[], b_open[];
      // Using H1 for RS base
      if(CopyClose(InpBenchmark, InpTFSlow, 1, 1, b_close) > 0 && CopyOpen(InpBenchmark, InpTFSlow, InpRSBars, 1, b_open) > 0)
         if(b_open[0] != 0)
            bench_change_pct = ((b_close[0] - b_open[0]) / b_open[0]) * 100.0;
     }

   string filename = "QuantScan_" + TimeToString(TimeCurrent(), TIME_DATE|TIME_MINUTES) + ".csv";
   StringReplace(filename, ":", "");
   StringReplace(filename, " ", "_");

   int file_handle = FileOpen(filename, FILE_CSV|FILE_WRITE|FILE_ANSI, ";");
   if(file_handle == INVALID_HANDLE)
      return;

// --- WRITE HEADER ---
   FileWrite(file_handle, sentiment_line);

// --- DYNAMIC COLUMNS ---
   string str_slow = EnumToString(InpTFSlow);
   StringReplace(str_slow, "PERIOD_", "");
   string str_mid  = EnumToString(InpTFMiddle);
   StringReplace(str_mid, "PERIOD_", "");
   string str_fast = EnumToString(InpTFFast);
   StringReplace(str_fast, "PERIOD_", "");

   string header = "";
   header += "TIME (" + InpBrokerTimeZone + ");";
   header += "SYMBOL;";
   header += "PRICE;";

// Layer 1
   header += StringFormat("TREND_SCORE_%s;", str_slow);
   header += StringFormat("TREND_QUAL_%s;", str_slow);
   header += StringFormat("ZONE_%s;", str_slow);
   header += StringFormat("REL_STRENGTH_%s;", str_slow);
   header += StringFormat("BETA_%s;", str_slow);
   header += StringFormat("ALPHA_%s;", str_slow);

// Layer 2
   header += StringFormat("MOMENTUM_%s;", str_mid);
   header += StringFormat("VOL_QUAL_%s;", str_mid);
   header += StringFormat("SQUEEZE_%s;", str_mid);
   header += StringFormat("Z_SCORE_%s;", str_mid);
   header += StringFormat("VOL_REGIME_%s;", str_mid);
   header += StringFormat("TSI_DIR_%s;", str_mid);

// Layer 3
   header += StringFormat("MOMENTUM_%s;", str_fast);
   header += StringFormat("VOL_QUAL_%s;", str_fast);
   header += StringFormat("TSI_DIR_%s;", str_fast);
   header += StringFormat("VELOCITY_%s;", str_fast);

// Composites
   header += "REVERSION_PROB;";
   header += "ABSORPTION";

   FileWrite(file_handle, header);

   PrintFormat("Scanning %d symbols...", total_symbols);

   for(int i=0; i<total_symbols; i++)
     {
      string sym = symbols[i];
      StringTrimLeft(sym);
      StringTrimRight(sym);
      QuantData data;
      ZeroMemory(data);

      if(RunQuantAnalysis(sym, bench_change_pct, data))
        {
         FileWrite(file_handle,
                   data.timestamp,
                   data.symbol,
                   DoubleToString(data.price, (int)SymbolInfoInteger(sym, SYMBOL_DIGITS)),
                   // Layer 1
                   DoubleToString(data.trend_score, 2),
                   DoubleToString(data.trend_qual, 2),
                   data.zone,
                   data.rel_strength_str,
                   data.beta_str,
                   data.alpha_str,
                   // Layer 2
                   DoubleToString(data.m15_momentum, 2),
                   DoubleToString(data.m15_vol_qual, 2),
                   data.m15_squeeze,
                   DoubleToString(data.m15_z_score, 2),
                   DoubleToString(data.m15_vola_regime, 2),
                   data.m15_tsi_dir,
                   // Layer 3
                   DoubleToString(data.m5_momentum, 2),
                   DoubleToString(data.m5_vol_qual, 2),
                   data.m5_tsi_dir,
                   DoubleToString(data.m5_velocity, 2),
                   // Composites
                   DoubleToString(data.rev_prob, 0) + "%",
                   data.absorption
                  );
        }
     }
   FileClose(file_handle);
   Print("Done. File: ", filename);
  }

//+------------------------------------------------------------------+
//| Core Logic                                                       |
//+------------------------------------------------------------------+
bool RunQuantAnalysis(string sym, double bench_change, QuantData &data)
  {
   data.timestamp = TimeToString(TimeCurrent(), TIME_DATE|TIME_MINUTES);
   StringReplace(data.timestamp, ".", ".");
   data.symbol    = sym;
   data.price     = SymbolInfoDouble(sym, SYMBOL_BID);

// =================================================================
// LAYER 1: CONTEXT (H1)
// =================================================================
   double slow_o[], slow_h[], slow_l[], slow_c[];
   long slow_v[];
   datetime slow_t[];
   if(!FetchData(sym, InpTFSlow, InpScanHistory, slow_t, slow_o, slow_h, slow_l, slow_c, slow_v))
      return false;

   double slow_atr = Calc_ATR(slow_o, slow_h, slow_l, slow_c, InpATRPeriod);
   if(slow_atr == 0)
      return false;

   data.trend_score = Calc_DSMA_Score(slow_o, slow_h, slow_l, slow_c, slow_atr);
   data.trend_qual  = Calc_ER(slow_o, slow_h, slow_l, slow_c, InpERPeriod);
   data.zone        = Calc_MurreyZone(sym, InpTFSlow);

// Benchmark Stats (Beta/Alpha)
   bool is_benchmark = (sym == InpBenchmark || sym == InpForexBench);
   if(is_benchmark)
     {
      data.rel_strength_str="BENCH";
      data.beta_str="1.0";
      data.alpha_str="0.0";
     }
   else
     {
      string bench_sym = InpBenchmark;
      if(IsForexPair(sym) && SymbolSelect(InpForexBench, true))
         bench_sym = InpForexBench;

      double bench_c[];
      if(CopyClose(bench_sym, InpTFSlow, 0, InpBetaLookback+2, bench_c) > InpBetaLookback)
        {
         CMathStatisticsCalculator stats;
         double asset_ret[], bench_ret[];
         int size = ArraySize(slow_c);
         double asset_sub[], bench_sub[];
         ArrayResize(asset_sub, InpBetaLookback);
         ArrayResize(bench_sub, InpBetaLookback);

         for(int k=0; k<InpBetaLookback; k++)
           {
            asset_sub[k] = slow_c[size - InpBetaLookback + k];
            bench_sub[k] = bench_c[ArraySize(bench_c) - InpBetaLookback + k];
           }

         stats.ComputeReturns(asset_sub, asset_ret);
         stats.ComputeReturns(bench_sub, bench_ret);
         double beta_val = stats.CalculateBeta(asset_ret, bench_ret);

         double a_tot = (asset_sub[InpBetaLookback-1] - asset_sub[0]) / asset_sub[0];
         double b_tot = (bench_sub[InpBetaLookback-1] - bench_sub[0]) / bench_sub[0];
         double alpha_val = stats.CalculateAlpha(a_tot, b_tot, beta_val);
         double rel_val = (a_tot - b_tot) * 100.0;

         data.rel_strength_str = DoubleToString(rel_val, 2) + "%";
         data.beta_str         = DoubleToString(beta_val, 2);
         data.alpha_str        = DoubleToString(alpha_val, 4);
        }
      else
        {
         data.rel_strength_str = "0%";
         data.beta_str = "0";
         data.alpha_str = "0";
        }
     }

// =================================================================
// LAYER 2: FLOW (M15 - Renamed from Trigger)
// =================================================================
   double mid_o[], mid_h[], mid_l[], mid_c[];
   long mid_v[];
   datetime mid_t[];
   if(!FetchData(sym, InpTFMiddle, InpScanHistory, mid_t, mid_o, mid_h, mid_l, mid_c, mid_v))
      return false;

   double mid_atr = Calc_ATR(mid_o, mid_h, mid_l, mid_c, InpATRPeriod);

   data.m15_momentum = Calc_LaguerreRSI(mid_o, mid_h, mid_l, mid_c);
   data.m15_vol_qual = Calc_RVOL(mid_v, InpRVOLPeriod);
   data.m15_squeeze  = Calc_Squeeze(sym, InpTFMiddle, mid_o, mid_h, mid_l, mid_c);
   data.m15_z_score  = Calc_ZScore(mid_o, mid_h, mid_l, mid_c, InpZScorePeriod);

   double mid_atr_f = Calc_ATR(mid_o, mid_h, mid_l, mid_c, 5);
   double mid_atr_s = Calc_ATR(mid_o, mid_h, mid_l, mid_c, 50);
   data.m15_vola_regime = (mid_atr_s!=0) ? mid_atr_f/mid_atr_s : 1.0;

   Calc_TSI_Dir(mid_o, mid_h, mid_l, mid_c, data.m15_tsi_dir);

// =================================================================
// LAYER 3: TRIGGER (M5 - NEW)
// =================================================================
   double fast_o[], fast_h[], fast_l[], fast_c[];
   long fast_v[];
   datetime fast_t[];
   if(!FetchData(sym, InpTFFast, 300, fast_t, fast_o, fast_h, fast_l, fast_c, fast_v))
      return false;

   double fast_atr = Calc_ATR(fast_o, fast_h, fast_l, fast_c, InpATRPeriod);

   data.m5_momentum = Calc_LaguerreRSI(fast_o, fast_h, fast_l, fast_c);
   data.m5_vol_qual = Calc_RVOL(fast_v, InpRVOLPeriod);
   Calc_TSI_Dir(fast_o, fast_h, fast_l, fast_c, data.m5_tsi_dir);
   data.m5_velocity = Calc_Velocity(fast_c, fast_atr, 3);

// =================================================================
// COMPOSITES
// =================================================================
// Rev Prob based on Flow (M15)
   double score = 0;
   if(MathAbs(data.m15_z_score) > 3.0)
      score += 40;
   else
      if(MathAbs(data.m15_z_score) > 2.0)
         score += 20;
   if(StringFind(data.zone, "Extreme") >= 0)
      score += 30;
   if(data.m15_momentum > 0.90 || data.m15_momentum < 0.10)
      score += 30;
   data.rev_prob = score;

// Absorption based on Flow (M15) or Trig (M5)? Standard is Flow due to volume significance.
// Let's stick to M15 for Absorption to filter M5 noise.
   int idx_cl = ArraySize(mid_c) - 2;
   if(idx_cl >= 0 && mid_atr > 0)
     {
      double body = MathAbs(mid_c[idx_cl] - mid_o[idx_cl]);
      CRelativeVolumeCalculator rv;
      rv.Init(InpRVOLPeriod);
      double bar_rvol = rv.CalculateSingle(ArraySize(mid_v), mid_v, idx_cl);
      if(bar_rvol > 2.0 && body < (0.4 * mid_atr))
         data.absorption = "YES";
      else
         data.absorption = "NO";
     }
   else
      data.absorption = "-";

   return true;
  }

//+------------------------------------------------------------------+
//| Velocity Calculation                                             |
//+------------------------------------------------------------------+
double Calc_Velocity(const double &close[], double atr, int period)
  {
   if(atr == 0)
      return 0;
   int total = ArraySize(close);
   if(total <= period+2)
      return 0;

   double sum_move = 0;
   for(int i=0; i<period; i++)
     {
      // [Total-2] is last closed.
      sum_move += MathAbs(close[total-2-i] - close[total-3-i]);
     }
   double avg_move = sum_move / period;

   return avg_move / atr;
  }

//+------------------------------------------------------------------+
//| HELPERS / WRAPPERS                                               |
//+------------------------------------------------------------------+
bool FetchData(string sym, ENUM_TIMEFRAMES tf, int count, datetime &t[], double &o[], double &h[], double &l[], double &c[], long &v[])
  {
   ArraySetAsSeries(t, false);
   ArraySetAsSeries(o, false);
   ArraySetAsSeries(h, false);
   ArraySetAsSeries(l, false);
   ArraySetAsSeries(c, false);
   ArraySetAsSeries(v, false);
   if(CopyTime(sym, tf, 0, count, t)!=count || CopyOpen(sym, tf, 0, count, o)!=count ||
      CopyHigh(sym, tf, 0, count, h)!=count || CopyLow(sym, tf, 0, count, l)!=count ||
      CopyClose(sym, tf, 0, count, c)!=count || CopyTickVolume(sym, tf, 0, count, v)!=count)
      return false;
   return true;
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Calc_ER(const double &o[], const double &h[], const double &l[], const double &c[], int p)
  {
   CEfficiencyRatioCalculator calc;
   if(!calc.Init(p))
      return 0;
   double buf[];
   int total = ArraySize(c);
   ArrayResize(buf, total);
   calc.Calculate(total, 0, PRICE_CLOSE, o, h, l, c, buf);
   return buf[total-2];
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Calc_ZScore(const double &o[], const double &h[], const double &l[], const double &c[], int p)
  {
   CZScoreCalculator calc;
   if(!calc.Init(p))
      return 0;
   double buf[];
   int total = ArraySize(c);
   ArrayResize(buf, total);
   calc.Calculate(total, 0, PRICE_CLOSE, o, h, l, c, buf);
   return buf[total-2];
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Calc_RVOL(const long &vol[], int p)
  {
   CRelativeVolumeCalculator calc;
   calc.Init(p);
   return calc.CalculateSingle(ArraySize(vol), vol, ArraySize(vol)-2);
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Calc_ATR(const double &o[], const double &h[], const double &l[], const double &c[], int p)
  {
   CATRCalculator calc;
   if(!calc.Init(p, ATR_POINTS))
      return 0;
   double buf[];
   int total=ArraySize(c);
   calc.Calculate(total, 0, o, h, l, c, buf);
   return buf[total-2];
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Calc_DSMA_Score(const double &o[], const double &h[], const double &l[], const double &c[], double atr)
  {
   CDSMACalculator calc;
   if(!calc.Init(InpDSMAPeriod))
      return 0;
   double buf[];
   int total=ArraySize(c);
   ArrayResize(buf, total);
   calc.Calculate(total, 0, PRICE_CLOSE, o, h, l, c, buf);
   if(atr==0)
      return 0;
   return (c[total-2] - buf[total-2]) / atr;
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
string Calc_Squeeze(string sym, ENUM_TIMEFRAMES tf, const double &o[], const double &h[], const double &l[], const double &c[])
  {
   int total = ArraySize(c);
   CBollingerBandsCalculator bb;
   bb.Init(InpSqueezeLength, InpBBMult, SMA);
   CKeltnerChannelCalculator kc;
   kc.Init(InpSqueezeLength, SMA, InpSqueezeLength, InpKCMult, ATR_SOURCE_STANDARD);
   double b_ma[], b_up[], b_lo[];
   ArrayResize(b_ma, total);
   ArrayResize(b_up, total);
   ArrayResize(b_lo, total);
   double k_ma[], k_up[], k_lo[];
   ArrayResize(k_ma, total);
   ArrayResize(k_up, total);
   ArrayResize(k_lo, total);
   bb.Calculate(total, 0, PRICE_CLOSE, o, h, l, c, b_ma, b_up, b_lo);
   kc.Calculate(total, 0, o, h, l, c, PRICE_CLOSE, k_ma, k_up, k_lo);
   int idx = total - 2;
   return ((b_up[idx] < k_up[idx]) && (b_lo[idx] > k_lo[idx])) ? "ON" : "OFF";
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Calc_LaguerreRSI(const double &o[], const double &h[], const double &l[], const double &c[])
  {
   CLaguerreRSICalculator calc;
   calc.Init(InpLaguerreGamma, 3, SMA);
   double lrsi[], sig[];
   int total=ArraySize(c);
   ArrayResize(lrsi, total);
   ArrayResize(sig, total);
   calc.Calculate(total, 0, PRICE_CLOSE, o, h, l, c, lrsi, sig);
   return lrsi[total-2] / 100.0;
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Calc_TSI_Dir(const double &o[], const double &h[], const double &l[], const double &c[], string &dir)
  {
   CTSICalculator calc;
   calc.Init(InpTSI_Slow, EMA, InpTSI_Fast, EMA, InpTSI_Signal, EMA);
   double tsi[], sig[], osc[];
   int total=ArraySize(c);
   ArrayResize(tsi, total);
   ArrayResize(sig, total);
   ArrayResize(osc, total);
   calc.Calculate(total, 0, PRICE_CLOSE, o, h, l, c, tsi, sig, osc);
   if(tsi[total-2] > sig[total-2])
      dir = "BULL";
   else
      dir = "BEAR";
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
string Calc_MurreyZone(string symbol, ENUM_TIMEFRAMES tf)
  {
   CMurreyMathCalculator calc;
   calc.Init(symbol, tf, InpMurreyPeriod, 0);
   double levels[];
   if(!calc.Calculate(levels))
      return "N/A";
   double price = iClose(symbol, tf, 1);
   if(price < levels[2])
      return "Extreme Low";
   if(price > levels[10])
      return "Extreme High";
   if(price >= levels[2] && price < levels[3])
      return "0/8-1/8 (Bottom)";
   if(price >= levels[3] && price < levels[4])
      return "1/8-2/8 (Weak)";
   if(price >= levels[4] && price < levels[6])
      return "2/8-4/8 (Lower)";
   if(price >= levels[6] && price < levels[8])
      return "4/8-6/8 (Upper)";
   if(price >= levels[8] && price < levels[9])
      return "6/8-7/8 (Weak)";
   return "7/8-8/8 (Top)";
  }
//+------------------------------------------------------------------+