143 lines
5.2 KiB
Markdown
143 lines
5.2 KiB
Markdown
|
# MathSqrt
|
|||
|
|
|
|||
|
|
Returns the square root of a number.
|
|||
|
|
|
|||
|
|
```
|
|||
|
|
double MathSqrt(
|
|||
|
|
double value // positive number
|
|||
|
|
);
|
|||
|
|
|
|||
|
|
```
|
|||
|
|
|
|||
|
|
Parameters
|
|||
|
|
|
|||
|
|
value
|
|||
|
|
|
|||
|
|
[in] Positive numeric value.
|
|||
|
|
|
|||
|
|
Return Value
|
|||
|
|
|
|||
|
|
Square root of value. If value is negative, MathSqrt returns NaN (indeterminate value).
|
|||
|
|
|
|||
|
|
Note
|
|||
|
|
|
|||
|
|
Instead of MathSqrt() you can use sqrt().
|
|||
|
|
|
|||
|
|
Example:
|
|||
|
|
|
|||
|
|
```
|
|||
|
|
#define GRAPH_WIDTH 750
|
|||
|
|
#define GRAPH_HEIGHT 350
|
|||
|
|
|
|||
|
|
#include <Graphics\Graphic.mqh>
|
|||
|
|
|
|||
|
|
CGraphic ExtGraph;
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
//| Script program start function |
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
void OnStart()
|
|||
|
|
{
|
|||
|
|
//--- get 11 values from 0 to 10 with step 1
|
|||
|
|
vector X(11,VectorArange);
|
|||
|
|
Print("vector X = \n",X);
|
|||
|
|
//--- calculate the square root of each value of the X vector
|
|||
|
|
X=MathSqrt(X);
|
|||
|
|
Print("MathSqrt(X) = \n",X);
|
|||
|
|
|
|||
|
|
//--- transfer the calculated values from the vector to the array
|
|||
|
|
double y_array[];
|
|||
|
|
X.Swap(y_array);
|
|||
|
|
|
|||
|
|
//--- draw a graph of the calculated vector values
|
|||
|
|
CurvePlot(y_array,clrDodgerBlue);
|
|||
|
|
|
|||
|
|
//--- wait for pressing the Escape or PgDn keys to delete the graph (take a screenshot) and exit
|
|||
|
|
while(!IsStopped())
|
|||
|
|
{
|
|||
|
|
if(StopKeyPressed())
|
|||
|
|
break;
|
|||
|
|
Sleep(16);
|
|||
|
|
}
|
|||
|
|
|
|||
|
|
//--- clean up
|
|||
|
|
ExtGraph.Destroy();
|
|||
|
|
/*
|
|||
|
|
result:
|
|||
|
|
vector X =
|
|||
|
|
[0,1,2,3,4,5,6,7,8,9,10]
|
|||
|
|
MathSqrt(X) =
|
|||
|
|
[0,1,1.414213562373095,1.732050807568877,2,2.23606797749979,2.449489742783178,2.645751311064591,2.82842712474619,3,3.16227766016838]
|
|||
|
|
*/
|
|||
|
|
}
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
//| Fill a vector with 'value' in 'step' increments |
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
template<typename T>
|
|||
|
|
void VectorArange(vector<T> &vec,T value=0.0,T step=1.0)
|
|||
|
|
{
|
|||
|
|
for(ulong i=0; i<vec.Size(); i++,value+=step)
|
|||
|
|
vec[i]=value;
|
|||
|
|
}
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
//| When pressing ESC, return 'true' |
|
|||
|
|
//| When pressing PgDn, take a graph screenshot and return 'true' |
|
|||
|
|
//| Otherwise, return 'false' |
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
bool StopKeyPressed()
|
|||
|
|
{
|
|||
|
|
//--- if ESC is pressed, return 'true'
|
|||
|
|
if(TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)!=0)
|
|||
|
|
return(true);
|
|||
|
|
//--- if PgDn is pressed and a graph screenshot is successfully taken, return 'true'
|
|||
|
|
if(TerminalInfoInteger(TERMINAL_KEYSTATE_PAGEDOWN)!=0 && MakeAndSaveScreenshot(MQLInfoString(MQL_PROGRAM_NAME)+"_Screenshot"))
|
|||
|
|
return(true);
|
|||
|
|
//--- return 'false'
|
|||
|
|
return(false);
|
|||
|
|
}
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
//| Create a graph object and draw a curve |
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
void CurvePlot(double &x_array[], double &y_array[], const color colour)
|
|||
|
|
{
|
|||
|
|
ExtGraph.Create(ChartID(), "Graphic", 0, 0, 0, GRAPH_WIDTH, GRAPH_HEIGHT);
|
|||
|
|
ExtGraph.CurveAdd(x_array, y_array, ColorToARGB(colour), CURVE_LINES);
|
|||
|
|
ExtGraph.IndentUp(30);
|
|||
|
|
ExtGraph.CurvePlotAll();
|
|||
|
|
string text1="Press ESC to delete the graph and stop the script, or";
|
|||
|
|
string text2="Press PgDn to create a screen, delete the graph and stop the script";
|
|||
|
|
ExtGraph.TextAdd(54, 9, text1, ColorToARGB(clrBlack));
|
|||
|
|
ExtGraph.TextAdd(54,21, text2, ColorToARGB(clrBlack));
|
|||
|
|
ExtGraph.Update();
|
|||
|
|
}
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
//| Take a screenshot and save the image to a file |
|
|||
|
|
//+------------------------------------------------------------------+
|
|||
|
|
bool MakeAndSaveScreenshot(const string file_name)
|
|||
|
|
{
|
|||
|
|
string file_names[];
|
|||
|
|
ResetLastError();
|
|||
|
|
int selected=FileSelectDialog("Save Picture", NULL, "All files (*.*)|*.*", FSD_WRITE_FILE, file_names, file_name+".png");
|
|||
|
|
if(selected<1)
|
|||
|
|
{
|
|||
|
|
if(selected<0)
|
|||
|
|
PrintFormat("%s: FileSelectDialog() function returned error %d", __FUNCTION__, GetLastError());
|
|||
|
|
return false;
|
|||
|
|
}
|
|||
|
|
|
|||
|
|
bool res=false;
|
|||
|
|
if(ChartSetInteger(0,CHART_SHOW,false))
|
|||
|
|
res=ChartScreenShot(0, file_names[0], GRAPH_WIDTH, GRAPH_HEIGHT);
|
|||
|
|
ChartSetInteger(0,CHART_SHOW,true);
|
|||
|
|
return(res);
|
|||
|
|
}
|
|||
|
|
|
|||
|
|
```
|
|||
|
|
|
|||
|
|
Result:
|
|||
|
|
|
|||
|
|
|
|||
|
|
|
|||
|
|
See also
|
|||
|
|
|
|||
|
|
[Real types (double, float)](/en/docs/basis/types/double), [Statistics](/en/docs/standardlibrary/mathematics/stat), [Scientific Charts](/en/docs/standardlibrary/graphics), [Client Terminal Properties](/en/docs/constants/environment_state/terminalstatus)
|