// Licensed under the Apache License, Version 2.0
// © mihakralj
//@version=6
indicator("Hamming Moving Average (HAMMA)", "HAMMA", overlay=true)

//@function Calculates HAMMA using Hamming window weighting
//@param source Series to calculate HAMMA from
//@param period Lookback period - FIR window size
//@returns HAMMA value, calculates from first bar using available data
//@optimized Uses Hamming window coefficients with O(n) complexity per bar due to lookback loop
hamma(series float source, simple int period) =>
    if period <= 0
        runtime.error("Period must be greater than 0")
    int p = math.min(bar_index + 1, period)
    var array<float> weights = array.new_float(1, 1.0)
    var int last_p = 1
    if last_p != p
        weights := array.new_float(p, 0.0)
        for i = 0 to p - 1
            float w = 0.54 - 0.46 * math.cos(2.0 * math.pi * i / (p - 1))
            array.set(weights, i, w)
        last_p := p
    float sum = 0.0
    float weight_sum = 0.0
    for i = 0 to p - 1
        float price = source[i]
        if not na(price)
            float w = array.get(weights, i)
            sum += price * w
            weight_sum += w
    nz(sum / weight_sum, source)

// ---------- Main loop ----------

// Inputs
i_period = input.int(10, "Period", minval=1)
i_source = input.source(close, "Source")

// Calculation
hamma_value = hamma(i_source, i_period)

// Plot
plot(hamma_value, "HAMMA", color=color.yellow, linewidth=2)