Initial commit: MQL5 Scripts Collection (MetaTrader 5)

2025-06-24 00:33:04 +01:00
commit 60a549d89c
1959 changed files with 31907 additions and 0 deletions
@@ -0,0 +1,51 @@
+//+------------------------------------------------------------------+
+//|                                           Demo_FileReadArray.mq5 |
+//|                        Copyright 2013, MetaQuotes Software Corp. |
+//|                                              http://www.mql5.com |
+//+------------------------------------------------------------------+
+#property copyright "Copyright 2013, MetaQuotes Software Corp."
+#property link      "http://www.mql5.com"
+#property version   "1.00"
+//--- display the window of input parameters when launching the script
+#property script_show_inputs
+//--- input parameters
+input string InpFileName="data.bin";
+input string InpDirectoryName="SomeFolder";
+//+------------------------------------------------------------------+
+//| Structure for storing price data                                 |
+//+------------------------------------------------------------------+
+struct prices
+  {
+   datetime          date; // date
+   double            bid;  // bid price
+   double            ask;  // ask price
+  };
+//+------------------------------------------------------------------+
+//| Script program start function                                    |
+//+------------------------------------------------------------------+
+void OnStart()
+  {
+//--- structure array
+   prices arr[];
+//--- file path
+   string path=InpDirectoryName+"//"+InpFileName;
+//--- open the file
+   ResetLastError();
+   int file_handle=FileOpen(path,FILE_READ|FILE_BIN);
+   if(file_handle!=INVALID_HANDLE)
+     {
+      //--- read all data from the file to the array
+      FileReadArray(file_handle,arr);
+      //--- receive the array size
+      int size=ArraySize(arr);
+      //--- print data from the array
+      for(int i=0;i<size;i++)
+         Print("Date = ",arr[i].date," Bid = ",arr[i].bid," Ask = ",arr[i].ask);
+      Print("Total data = ",size);
+      //--- close the file
+      FileClose(file_handle);
+     }
+   else
+      Print("File open failed, error ",GetLastError());
+  }
+//+------------------------------------------------------------------+