Initial commit: MQL5 Scripts Collection (MetaTrader 5)

2025-06-24 00:33:04 +01:00
commit 60a549d89c
1959 changed files with 31907 additions and 0 deletions
@@ -0,0 +1,19 @@
+# 🚀 Unlock the Power of Trading!
+
+Welcome to this open-source trading project. Here you will find powerful tools to enhance your trading journey. If you find this project useful, please consider starring ⭐, sharing, or donating to support further development!
+
+---
+
+**Support the project:**
+- Star this repository on GitHub
+- Share it with your trading friends
+- [Donate here](https://www.paypal.com/donate/?hosted_button_id=YOUR_BUTTON_ID) to help us grow!
+
+---
+![Screenshot](script.png)
+
+## Source Files
+- `demo_filedelete.mq5`
+
+---
+> Made with ❤️ for the trading community.
@@ -0,0 +1,73 @@
+//+------------------------------------------------------------------+
+//|                                              Demo_FileDelete.mq5 |
+//|                        Copyright 2013, MetaQuotes Software Corp. |
+//|                                              http://www.mql5.com |
+//+------------------------------------------------------------------+
+#property copyright "Copyright 2013, MetaQuotes Software Corp."
+#property link      "http://www.mql5.com"
+#property version   "1.00"
+//--- show the window of input parameters when launching the script
+#property script_show_inputs
+//--- date for old files
+input datetime InpFilesDate=D'2013.01.01 00:00';
+//+------------------------------------------------------------------+
+//| Script program start function                                    |
+//+------------------------------------------------------------------+
+void OnStart()
+  {
+   string   file_name;      // variable for storing file names
+   string   filter="*.txt"; // filter for searching the files
+   datetime create_date;    // file creation date
+   string   files[];        // list of file names
+   int      def_size=25;    // array size by default
+   int      size=0;         // number of files
+//--- allocate memory for the array
+   ArrayResize(files,def_size);
+//--- receive the search handle in the local folder's root
+   long search_handle=FileFindFirst(filter,file_name);
+//--- check if FileFindFirst() executed successfully
+   if(search_handle!=INVALID_HANDLE)
+     {
+      //--- searching files in the loop
+      do
+        {
+         files[size]=file_name;
+         //--- increase the array size
+         size++;
+         if(size==def_size)
+           {
+            def_size+=25;
+            ArrayResize(files,def_size);
+           }
+         //--- reset the error value
+         ResetLastError();
+         //--- receive the file creation date
+         create_date=(datetime)FileGetInteger(file_name,FILE_CREATE_DATE,false);
+         //--- check if the file is old
+         if(create_date<InpFilesDate)
+           {
+            PrintFormat("%s file deleted!",file_name);
+            //--- delete the old file
+            FileDelete(file_name);
+           }
+        }
+      while(FileFindNext(search_handle,file_name));
+      //--- close the search handle
+      FileFindClose(search_handle);
+     }
+   else
+     {
+      Print("Files not found!");
+      return;
+     }
+//--- check what files have remained
+   PrintFormat("Results:");
+   for(int i=0;i<size;i++)
+     {
+      if(FileIsExist(files[i]))
+         PrintFormat("%s file exists!",files[i]);
+      else
+         PrintFormat("%s file deleted!",files[i]);
+     }
+  }
+//+------------------------------------------------------------------+